write more efficient sparql query

Question

I'm using GraphDB and the triple store is spatially indexed.

When I'm using this query, called Q1:

PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX omgeo: <http://www.ontotext.com/owlim/geo#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 
select ?a ?lat ?long 
WHERE {
    ?a omgeo:within(22.92 -142.38 75.23 183.69) . 
    ?a geo-pos:lat ?lat . 
    ?a geo-pos:long ?long .

} limit 5000

It only takes less than a second, omgeo:within(22.92 -142.38 75.23 183.69) is using the spatial index of the triple store.

Also, when I use this query, called Q2:

PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX omgeo: <http://www.ontotext.com/owlim/geo#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 
select ?a ?lat ?long 
WHERE {
    ?a a ?o .
    filter(?o = someclass) .
    ?a geo-pos:long ?long .

} limit 5000

or this query, called Q3:

PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX omgeo: <http://www.ontotext.com/owlim/geo#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 
select ?a ?lat ?long 
WHERE {
    ?a a someclass .    
    ?a geo-pos:lat ?lat . 
    ?a geo-pos:long ?long .
} limit 5000

They return the same results and both take about 1 second.

But if I use this query, called Q4:

PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#> 
PREFIX omgeo: <http://www.ontotext.com/owlim/geo#> 
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> 
select ?a ?lat ?long 
WHERE {
    ?a omgeo:within(22.92 -142.38 75.23 183.69) . 
    ?a a ?o .
    filter(?o = someclass) .
    ?a geo-pos:lat ?lat . 
    ?a geo-pos:long ?long .

} limit 5000

It takes more than 60 seconds. Do you know why this happens? Even if Q2 and Q3 returns 0 result, which means that the someclass I queried about has no instance, Q4 still takes more than 60 seconds. Is there a more efficient way to write Q4?

Although your earlier query seems to have run fast enough, filter (?var = ...) is always a little suspect. values ?var { ... } may be better, since it's conceptually saying "use these values of this variable" whereas the filter says "get a bunch of solutions and then remove ones that don't match".a good engine should optimize this filter, but it's one area to look into, at least. — Joshua Taylor
– Joshua Taylor, Commented Oct 8, 2015 at 12:11
@JoshuaTaylor I tried 'values ?var {...}', it's the same as Q4. I also tried using 'PREFIX geo-pos: <w3.org/2003/01/geo/wgs84_pos#> PREFIX geo: <w3.org/2003/01/geo/wgs84_pos#> PREFIX omgeo: <ontotext.com/owlim/geo#> PREFIX xsd: <w3.org/2001/XMLSchema#> select ?a ?lat ?long WHERE { ?a omgeo:within(22.92 -142.38 75.23 183.69) . ?a a someclass . ?a geo-pos:lat ?lat . ?a geo-pos:long ?long . } limit 5000' it also takes about 60 seconds, the same as Q4 — al3xtouch
– al3xtouch, Commented Oct 8, 2015 at 15:03

Joshua Taylor · Accepted Answer · 2015-10-08 15:07:49Z

2

If a query like your first two runs sufficiently quickly, and your intent is just to filter down the results, a query like the one you've written should do it for you (as far as I can tell). However, you could also combine the queries by making one a subquery. This shouldn't make a difference, but it might help. I.e., you can do something like:

select ?a ?lat ?long {
  values ?o { <some-class> }
  ?a a ?o .
  { select ?a ?lat ?long  {
      ?a omgeo:within(22.92 -142.38 75.23 183.69) . 
      ?a geo-pos:lat ?lat . 
      ?a geo-pos:long ?long .
    } limit 5000 }
}

answered Oct 8, 2015 at 15:07

Joshua Taylor

86.2k9 gold badges164 silver badges379 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

al3xtouch Over a year ago

Thanks, this one is much faster. It might have something to do with how the query is really implemented under the hood. Maybe graphdb knows how to fix it.

Vladimir Alexiev · Accepted Answer · 2017-01-13 18:55:25Z

0

Why not just use ?a a someclass ?
Have you tried Explain Query? http://graphdb.ontotext.com/documentation/standard/explain-plan.html

answered Jan 13, 2017 at 18:55

Vladimir Alexiev

2,6411 gold badge22 silver badges33 bronze badges

Collectives™ on Stack Overflow

write more efficient sparql query

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related