Capture CMD output with AutoHotkey

New recommended 2 ways of doing as of Nov 2019 - https://www.autohotkey.com/docs/FAQ.htm#output:

Method 1: via temporary file

Testing shows that due to file caching, a temporary file can be very fast for relatively small outputs. In fact, if the file is deleted immediately after use, it often does not actually get written to disk. For example:

RunWait %ComSpec% /c dir > C:\My Temp File.txt
FileRead, VarToContainContents, C:\My Temp File.txt
FileDelete, C:\My Temp File.txt

Method 2: via Shell.Exec()

The same doc section goes on as follows:

To avoid using a temporary file (especially if the output is large), consider using the Shell.Exec() method as shown in the examples for the Run command.

And you'll find the example mentioned on the documentation for the Run command:

MsgBox % RunWaitOne("dir " A_ScriptDir)
RunWaitOne(command) {
    shell := ComObjCreate("WScript.Shell")
    exec := shell.Exec(ComSpec " /C " command)
    return exec.StdOut.ReadAll()
}

Note: method 2 (shell.Exec) will cause quick display of a cmd window. You can reduce the duration of its appearance by putting these lines at the top of your script, which will also cause the flickering to happen only once the first time you call the cmd command. From https://autohotkey.com/board/topic/92032-how-to-hide-a-wscript-comspec-window/:

;The 2 calls below: the cmd window will flash once quickly at first run
;This is to mitigate the flickering every time we call shell.Exec
DllCall("AllocConsole")
WinHide % "ahk_id " DllCall("GetConsoleWindow", "ptr")

Just an update to @amynbe answer.

MsgBox % RunWaitOne("dir " A_ScriptDir)


RunWaitOne(command) {
    shell := ComObjCreate("WScript.Shell")
    exec := shell.Exec(ComSpec " /C " command)
    return exec.StdOut.ReadAll()
}

Note: the latter method (shell.Exec) will cause quick display of a cmd window. You can reduce > the duration of its appearance by putting these lines at the top of > your script, which will also cause the flickering to happen only once > the first time you call the cmd command.

You can just do this below to hide cmd and avoid flashing.

v1

RunWaitOne(command) {
    DetectHiddenWindows On
    Run %ComSpec%,, Hide, pid
    WinWait ahk_pid %pid%
    DllCall("AttachConsole", "UInt", pid)
     
    shell := ComObjCreate("WScript.Shell")
    exec := shell.Exec(ComSpec " /C " command)
    result := exec.StdOut.ReadAll()
     
    DllCall( "FreeConsole" )
    Process, Close, %pid%
    return result
}

v2

RunWaitOne(command) {
    DetectHiddenWindows(1)
    Run(A_ComSpec,, "Hide", &pid)
    WinWait("ahk_pid" pid)
    DllCall("AttachConsole", "UInt", pid)
  
    shell := ComObject("WScript.Shell")
    exec := shell.Exec(A_ComSpec " /C " command)
    result := exec.StdOut.ReadAll()
   
    DllCall("FreeConsole")
    ProcessClose(pid)
    return result
} 

If you don't need a live output, you could use the cmd box itself to save a text file of itself and then you could have autohotkey detect when the console's PID finished (using the returned result of runwait and read the outputted file into memory.

So you could do this in your run command (just a regular cmd parameter):

ipconfig > myoutput.txt
exit

Now you have a text file with the ipconfig output in it.

OR you could do the same thing, but instead of outputting to a text file, you could output to the clipboard, like this:

ipconfig | clip

Then, since the output is on the clipboard, you can easily grab it into autohotkey.

How about this script, StdoutToVar ?
It has support for 64bit consoles. http://www.autohotkey.com/board/topic/15455-stdouttovar/page-7

This has been bugging me for some time now - and finally this works !

The only prerequisite for this is MS sqlcmd.exe, a database called AHK_Dev and of course AHK_DBA to read the value when you wish to make use of it.

PS. make sure you replace {yourDir} and {yourServer} with you own values!

USE AHK_DEV
CREATE TABLE [dbo].[AHK_DOS]([dos_out] [varchar](max) NULL) ON [PRIMARY];
insert into ahk_dos select 'empty'

Create the follow script ... call it dos_out.bat

@echo off
if "%1" == "" ( 
    set v_cmd=""
) else (
    set v_cmd=%1
)
set v_cmd=%v_cmd:~1,-1%
SETLOCAL ENABLEDELAYEDEXPANSION
if "!v_cmd!" == "" (
    set v_cmd="echo ... %COMPUTERNAME% %USERNAME% %DATE% %TIME%"
    set v_cmd=!v_cmd:~1,-1!
)
set v_data=""
FOR /F "usebackq delims=¬" %%i in (`!v_cmd!`) do (
    set v_data="!v_data:~1,-1!%%i~"
)
set q_cmd="set nocount on;update ahk_dos set dos_out=N'!v_data:~1,-1!'"
"{yourDir}\Microsoft SQL Server\90\Tools\Binn\sqlcmd.exe" -S {yourServer} -E -d ahk_dev -Q !q_cmd! -W 
set q_cmd="set nocount on;select len(dos_out) as out_len, dos_out from ahk_dos"
"{yourDir}\Microsoft SQL Server\90\Tools\Binn\sqlcmd.exe" -S {yourServer} -E -d ahk_dev -Q !q_cmd! -W -w 8000
pause

you can run it from AHK using...

dosCmd2db(c) {
runwait, {yourDir\}dos_out.bat "%c%", , , dospid
msgbox %dospid% closed
}
dosCmd2db("")
dosCmd2db("echo This is a test")
dosCmd2db("dir")

As the same field is being updated each time, you would clearly need to do something between each one to make this example useful!

Try it, and let me know how you get on

Regards, Geoff