How to get the current Wi-Fi SSID in Swift on macOS Sequoia and higher? [duplicate]

A faster version for Sequoia 15.0–15.5 (which also determines the correct WiFi interface enX):

ipconfig getsummary "$(networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $NF}')" | grep '  SSID : ' | awk -F ': ' '{print $2}'

Takes 46 ms vs. 3.8 s on my system.

As of macOS 15.6, the above no longer works & returns "<redacted>". Even programmatic access through CoreWLAN appears to now require a (developer/non-ad-hoc) signed executable with location entitlements, meaning it can't really be run from a script.

There is an even-hackier CLI work-around (taking 42 ms):

en="$(networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $NF}')"; ipconfig getsummary "$en" | grep -Fxq "  Active : FALSE" || networksetup -listpreferredwirelessnetworks "$en" | sed -n '2s/^\t//p'

Note that this won't work properly on some older versions of macOS (macOS 12 tested), because the list does not appear to be sorted in the same manner. Use an older command for getting the SSID.

Also, if GUI scripting is possible in your environment, something like the following AppleScript is an option. It takes 26 ms on my system. Note, though, that GUI scripting is prone to breakage (though perhaps not moreso than what Apple has been doing with all the networking command line tools lately! 😤). It's only tested in macOS 15 and is unlikely to work in Tahoe without modification.

tell application "System Events"
    tell application process "Control Center"
        -- Prepare UI element references.
        set wifi_menu_bar_item_ref to a reference to (first menu bar item of menu bar 1 whose value of attribute "AXIdentifier" is "com.apple.menuextra.wifi")
        set wifi_enabled_toggle_ref to a reference to (value of checkbox 1 of group 1 of window "Control Center")
        set wifi_connected_toggle_ref to a reference to (last checkbox of UI element 1 of scroll area 1 of group 1 of window "Control Center" where its value is true and value of its attribute "AXIdentifier" starts with "wifi-network-")
        set ssid_identifier_ref to a reference to (value of attribute "AXIdentifier" of wifi_connected_toggle_ref)
        
        -- Open the WiFi menu if it's not already open.
        if not (exists wifi_enabled_toggle_ref) then
            click wifi_menu_bar_item_ref
            delay 0.01 -- Just in case; doesn't appear necessary in testing.
        end if
        
        -- Get the SSID.
        set wifi_enabled to contents of wifi_enabled_toggle_ref as boolean
        if wifi_enabled then
            if exists wifi_connected_toggle_ref then
                set ssid_identifier to contents of ssid_identifier_ref
                set ssid to text 14 thru -1 of ssid_identifier
            else -- WiFi disconnected.
                set ssid to ""
            end if
        else -- WiFi disabled.
            set ssid to ""
        end if
        
        -- Close the WiFi menu.
        click wifi_menu_bar_item_ref
        
        -- Return the ssid.
        return ssid
    end tell
end tell

Note that this requires the WiFi menu bar item to be always visible.

The BSSID has similarly been restricted (prior to macOS 15.6); here's a version of the above GUI AppleScript that retrieves the BSSID (without needing sudo):

tell application "System Events"
    tell application process "Control Center"
        -- Prepare UI element references.
        set wifi_menu_bar_item_ref to a reference to (first menu bar item of menu bar 1 whose value of attribute "AXIdentifier" is "com.apple.menuextra.wifi")
        set wifi_enabled_toggle_ref to a reference to (value of checkbox 1 of group 1 of window "Control Center")
        set menu_buttons_group_ref to a reference to (group 1 of window "Control Center")
        set bssid_label_ref to a reference to (static text "BSSID:" of UI element 1 of scroll area 1 of group 1 of window "Control Center")
        set bssid_ref to a reference to (value of static text after static text after bssid_label_ref)
        
        -- Open the secondary WiFi menu if it's not already open.
        set some_menu_open to (exists wifi_enabled_toggle_ref)
        set secondary_menu_open to some_menu_open and (count buttons of menu_buttons_group_ref) is 4
        set primary_menu_open to some_menu_open and not secondary_menu_open
        if primary_menu_open then
            click wifi_menu_bar_item_ref -- Close the primary menu.
            delay 1.5
        end if
        if not secondary_menu_open then
            key down option
            click wifi_menu_bar_item_ref -- Open the secondary menu.
            key up option
            delay 0.01 -- Just in case; doesn't appear necessary in testing.
        end if
        
        -- Get the BSSID.
        if (exists bssid_label_ref) then
            set bssid to contents of bssid_ref
        else -- WiFi disconnected/disabled.
            if contents of wifi_enabled_toggle_ref as boolean then -- WiFi disconnected.
                set bssid to "00:00:00:00:00:00"
            else -- WiFi disabled.
                set bssid to "00:00:00:00:00:00"
            end if
        end if
        
        -- Close the WiFi menu.
        click wifi_menu_bar_item_ref
        
        -- Return the ssid.
        return bssid
    end tell
end tell

As posted here: Apple Forum

and here: Ask Different

Sequoia broke something when you try to retrieve the SSID. Currently, the only available solution is to use this:

system_profiler SPAirPortDataType | awk '/Current Network/ {getline;$1=$1;print $0 | "tr -d ':'";exit}'

That integrated into Swift becomes this:

import Foundation

func getWiFiNetworkName() -> String {
    let process = Process()
    process.executableURL = URL(fileURLWithPath: "/bin/bash")
    process.arguments = ["-c", "system_profiler SPAirPortDataType | awk '/Current Network/ {getline;$1=$1;print $0 | \"tr -d \':\'\";exit}'"]

    let pipe = Pipe()
    process.standardOutput = pipe

    do {
        try process.run()
    } catch {
        return "Error executing process."
    }

    let data = pipe.fileHandleForReading.readDataToEndOfFile()
    let output = String(data: data, encoding: .utf8)?.trimmingCharacters(in: .whitespacesAndNewlines)

    return output ?? "No Wi-Fi network detected."
}

let networkName = getWiFiNetworkName()
print("Connected to: \(networkName)")

If I find a better solution, I will update this post with the new one.

Here is a method to retrieve the Wi-Fi SSID using a bash script: MacOS: 15.3 (24D60) I tested a lot of methods and it worked

(ipconfig getsummary "$(networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $NF}')" | grep ' SSID : ' | awk -F ': ' '{print $2}')

Here is a method to retrieve the Wi-Fi SSID using a bash script:

#!/bin/bash
# Get the name of the Wi-Fi interface
wifi_interface=$(networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $2}')
echo "Debug: Wi-Fi Interface: $wifi_interface"  # Debug statement

# Use networksetup to get the SSID
if [ -n "$wifi_interface" ]; then
    wifi_name=$(ipconfig getsummary "$(networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $NF}')" | grep ' SSID : ' | awk -F ': ' '{print $2}')
    echo "Debug: Wi-Fi Name: $wifi_name"  # Debug statement
else
    echo "Debug: No Wi-Fi interface found."  # Debug statement for when no interface is detected
fi

Output:

Debug: Wi-Fi Name: This_Is_real_wifi_name

This script retrieves the current Wi-Fi SSID by first identifying the Wi-Fi interface and then using ipconfig to get the SSID associated with that interface. The debug statements help trace the values being processed.

See caveats above regarding macOS ≥15.6.

Here is the swift function wrapped @David P.'s answer and @dot1q's answer.

func getCurrentWiFiSSID(interfaceName:String? = "en0") -> String? {
    var command = "";
    if(interfaceName == nil){
        command = #"networksetup -listallhardwareports | awk '/Wi-Fi|AirPort/{getline; print $NF}' | xargs ipconfig getsummary"#
    }
    else{
        command = "ipconfig getsummary \(interfaceName ?? "en0")"
    }
    command += #" | awk -F ' SSID : '  '/ SSID : / {print $2}'"#
    let process = Process()
    let pipe = Pipe()
    process.standardOutput = pipe
    process.standardError = pipe
    process.arguments = ["-c", command]
    process.launchPath = "/bin/bash"
    
    
    process.launch()
    process.waitUntilExit()
    
    let data = pipe.fileHandleForReading.readDataToEndOfFile()
    guard let output = String(data: data, encoding: .utf8)?
        .trimmingCharacters(in: .whitespacesAndNewlines),
          !output.isEmpty else {
        return nil
    }
    
    return output
}

As far as I know, the device en0 is usually a WiFi adapter device (and some open source code do the same), so if you call the function directly, it will skip the WiFi adapter seeking process and earn a better performance. You can call this function with getCurrentWiFiSSID(interfaceName: nil) to reproduce the process in @David P.'s answer.