294

Can somebody remember what was the command to create an empty file in MSDOS using BAT file?

Improve this question
4
  • 3
    Also at stackoverflow.com/questions/1702762, "How to create an empty file at the command line?". Commented Jan 25, 2010 at 12:13
  • 6
    You aren't confusing DOS and cmd.exe, are you? Commented May 10, 2012 at 3:56
  • 1
    READ ME: Set-Content "your_file.txt" .gitignore -Encoding utf8 this is case-sensitive and forces utf8 encoding! (I also posted this as an answer). Commented Jan 25, 2020 at 6:26
  • 2
    Does this answer your question? How can I create an empty file at the command line in Windows? Commented Jul 10, 2023 at 8:32

13 Answers 13

Reset to default
413 
copy NUL EmptyFile.txt

DOS has a few special files (devices, actually) that exist in every directory, NUL being the equivalent of UNIX's /dev/null: it's a magic file that's always empty and throws away anything you write to it. Here's a list of some others; CON is occasionally useful as well.

To avoid having any output at all, you can use

copy /y NUL EmptyFile.txt >NUL

/y prevents copy from asking a question you can't see when output goes to NUL.

Improve this answer
Sign up to request clarification or add additional context in comments.

9 Comments

+1 - the question does state an empty file, so the accepted answer is wrong.
DannySmurf's solution actually does create an empty file -- a newline goes to stdout, nothing goes to stderr (directed into the new file). But thanks for the +1 anyways
type nul > EmptyFile.txt is shortest solution. Still your answer is better then accepted solution, cause your file will be really empty. +1
Warning: yes the question was on how to create an empty file, however usually you want to "make sure the file exists". When using the copy /Y NUL command it might erase existing content. If you are used to Unix' touch command, this might not at all be what you expect .) Using type NUL >> emptyfile.txt is safer in this regard.
I couldn't find any information on CON, aside from that linked in this answer. Could someone share some light reading?
|
259 
echo. 2>EmptyFile.txt

This redirects output stream 2 (stderr) to a file. The command echo doesn't output anything to stderr, so the file becomes empty.

Plain echo would work too, but echo. is better because it doesn't print the useless and potentially confusing message ECHO is on.

Improve this answer

12 Comments

This echoes a newline to stdout, though... my answer doesn't.
Sometimes it's relevant; I used to have touch lying around until I got the idea of just copying NUL (or type NUL>file) for the purpose of getting 0-byte files. :-)
To merge ephemient's answer and this one, you could do: "echo. >NUL 2>EmptyFile.txt" to achieve the same results without outputting a newline
Why is . in echo.
@Reegan If you used echo 2 without the ., the console would read "ECHO is off." Using echo. 2 effectively silences console output by only displaying a newline.
|
208 
type NUL > EmptyFile.txt

After reading the previous two posts, this blend of the two is what I came up with. It seems a little cleaner. There is no need to worry about redirecting the "1 file(s) copied." message to NUL, like the previous post does, and it looks nice next to the ECHO OutputLineFromLoop >> Emptyfile.txt that will usually follow in a batch file.

Improve this answer

4 Comments

+1 this is the natural one that first comes to mind, not the contrivances with stderr etc.
You are correct. This method avoides the /y flag on the copy command.
Short and easy. A few other solutions here do not create a new file of zero bytes!
This should have been the accepted answer. About as clean and simple as it gets.
84

Techniques I gathered from other answers:

Makes a 0 byte file a very clear, backward-compatible way:

type nul >EmptyFile.txt

idea via: anonymous, Danny Backett, possibly others, myself inspired by JdeBP's work

A 0 byte file another way, it's backward-compatible-looking:

REM. >EmptyFile.txt

idea via: Johannes

A 0 byte file 3rd way backward-compatible-looking, too:

echo. 2>EmptyFile.txt

idea via: TheSmurf

A 0 byte file the systematic way probably available since Windows 2000:

fsutil file createnew EmptyFile.txt 0

idea via: Emm

A 0 bytes file overwriting readonly files

ATTRIB -R filename.ext>NUL
(CD.>filename.ext)2>NUL

idea via: copyitright

A single newline (2 bytes: 0x0D 0x0A in hex notation, alternatively written as \r\n):

echo.>AlmostEmptyFile.txt

Note: no space between echo, . and >.

idea via: How can you echo a newline in batch files?

edit It seems that any invalid command redirected to a file would create an empty file. heh, a feature! compatibility: uknown

TheInvisibleFeature <nul >EmptyFile.txt

A 0 bytes file: invalid command/ with a random name (compatibility: uknown):

%RANDOM%-%TIME:~6,5% <nul >EmptyFile.txt

via: great source for random by Hung Huynh

edit 2 Andriy M points out the probably most amusing/provoking way to achieve this via invalid command

A 0 bytes file: invalid command/ the funky way (compatibility: unknown)

*>EmptyFile.txt

idea via: Andriy M

A 0 bytes file 4th-coming way: 

break > file.txt

idea via: foxidrive thanks to comment of Double Gras!

Improve this answer

7 Comments

It's type nul ..., not type <nul ..., actually.
@AndriyM thanks you're right I made the edit! Didn't notice because interestingly enough it works with the wrong one. which may mean that any invalid command redirected to a filename would create an empty file! just tried with NonExistentCommand <nul >EmptyFile.txt and it worked
since it would be unsafe to rely on a hardcoded command name expecting it to be "invalid", I added a randomized command name option
Yet another one: break > file.txt, props foxidrive
And most of the commands can be used with >> if you need "must exist but should not be truncated if exist" (like Unix touch does)
|
27

REM. > empty.file

Improve this answer

4 Comments

I'm stuck on Windows CE, and this is the only answer that creates and empty file! The other approaches either add a blank line or simply don't work...
The only problem with this solution is that if there is a file called REM in the current directory, and you type REM., cmd will respond with "'rem.' is not recognized as an internal or external command, operable program or batch file."
@DodgyCodeException, using rem/ instead of rem. solves that problem...
@aschipfl thanks, that's interesting. It's also interesting how this answer from 2010 has comments spaced from each other by several years. A slowwwww conversation!
11

If there's a possibility that the to be written file already exists and is read only, use the following code:

ATTRIB -R filename.ext
CD .>filename.ext

If no file exists, simply do:

CD .>filename.ext

(updated/changed code according to DodgyCodeException's comment)

To supress any errors that may arise:

ATTRIB -R filename.ext>NUL
(CD .>filename.ext)2>NUL
Improve this answer

1 Comment

The only problem with this solution is that if there is a file called CD (no extension) in the current directory, and you type CD., cmd will respond with "'CD.' is not recognized as an internal or external command, operable program or batch file." If you instead type CD . (with a space before the dot) it will work.
9

One more to add to the books - short and sweet to type.

break>file.txt
break>"file with spaces in name.txt"
Improve this answer

6 Comments

I guess we woyld skip the quotes
@NamGVU The quotes are used in the target filename, if you choose to use long filename elements such as space or & etc. They are not part of the file contents.
Yeah I agree ^^ Permission to update yours as discussed.
@NamGVU The quotes are able to be left in place with or without a long filename. I guess if it's typed from the command line with a short filename, then you wouldn't want unnecessary typing.
I suggest removing the second line from this answer. IMO this is the best answer on the question so far, but the second line doesn't really add value unless the person trying to use it doesn't know the basics of white-space handling for command-line.
|
7 
fsutil file createnew file.cmd 0
Improve this answer

2 Comments

The FSUTIL utility requires that you have administrative privileges.
fsutil is not a standard utility in MS-DOS.
2

You can use a TYPE command instead of COPY. Try this:

TYPE File1.txt>File2.txt

Where File1.txt is empty.

Improve this answer

2 Comments

You can also do type NUL>File2.txt
BTW, how to get File1.txt?
1

You can also use SET to create a null byte file as follows

set x=x > EmptyFile.txt

Or if you don't want to create an extra variable reassign an existing variable like

set PROMPT=%PROMPT% > EmptyFile.txt

or like this:

set "PROMPT=%PROMPT%" > EmptyFile.txt
Improve this answer

Comments

1

There are infinite approaches.

Commands that output nothing:

break
cls
color
goto
pushd
popd
prompt
title

Weird Commands:

CD.
REM.
@echo off
cmd /c
START >FILE

The outdated print command produces a blank file:

print /d:EMPTY_TEXT_FILE nul
Improve this answer

Comments

-3

The easiest way is:

echo. > Filename.txt

Improve this answer

2 Comments

This will create a file with a space character followed by a carriage return character followed by a new line character – not an empty file.
Worth looking at my answer (below) because it changes the encoding.
-3

IMPORTANT:

If you don't set the encoding, many softwares can break. git is a very popular example.

Set-Content "your_ignore_file.txt" .gitignore -Encoding utf8 this is case-sensitive and forces utf8 encoding!

Improve this answer

5 Comments

How is the encoding relevant for creating an empty file? A null byte file doesn't need any encoding and it's tricky to mark it with a BOM (0 bytes)
@jeb because people fill empty files, and when filled files are used as settings files, they create errors when they are not UTF8. In fact, I would say people almost always fill files and don't leave them blank, and I wouldn't use any other method to create a blank file that I later intended to alter because I nearly always want to be certain that my files are UTF8. For example, the .git tutorial on github asks the user to make a blank file which is filled later, and the other method makes a file with weird Windows encoding.
@Wolfpack'08, the file encoding is not stored in a special attribute or in some other magical secret area, it is just reflected by the data it contains; if there is no data, there cannot be an encoding…
@aschipfl A blank file must contain some data, then. If you create a blank file and explicitly flag utf8, the file works after it is later populated; on the other hand, if you create a blank file and ostensibly allow default encoding (ASCII), when you later fill the file it will break whatever program requires UT8 encoding. I have first-hand experience of this, and anybody can test it. Regardless of your incredulity, this is demonstrably true and tolerates empirical testing: I think the negative feedback is totally unwarranted and damages the accessibility of this important info. Prove it.
A blank file is a blank file, there is no data inside; otherwise, it would not be blank (empty, 0 bytes), would it? You seem to work with a versioning tool (git), which stores some meta-data for each file, apparently including its encoding. But the blank file itself definitely does not hold any encoding setting, neither in the data area (0 bytes obviously hold no information), nor in the file table of the file system (FAT, NTFS, or whatever you may use)…

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.