How to generate two output files from if/else statement by using awk?

Question

From the info below:

$ cat access.dat
2025/01/01T10:00:01 "GET" /path/resource/api1 User1 500
2025/01/01T10:00:01 "DELETE" /path/resource/api1 User1 503
2025/01/01T04:00:01 "GET" /path/resource/api1 User1 500
2025/01/01T03:00:01 "GET" /path/resource/api1 User1 503
2025/01/01T05:00:01 "PUT" /path/resource/api1 User2 500
2025/01/01T06:00:01 "GET" /path/resource/api1 User1 200
2025/01/01T07:00:01 "GET" /path/resource/api1 User1 201
2025/01/01T08:00:01 "GET" /path/resource/api2 User1 500
2025/01/01T09:00:01 "POST" /path/resource/api2 User2 500
2025/01/01T10:00:01 "POST" /path/resource/api2 User1 400
2025/01/01T11:00:01 "GET" /path/resource/api2 User2 404

I am trying to generate an awk script with if else statement. When doing

cat access.dat | awk '{if ($NF>=400) {print $0}} > failure.dat

the output file is generated successfully. But when adding

cat access.dat | awk '{if ($NF>=400) {print $0} > failure.dat else {print$0} > success.dat}

is marking error. What is wrong in my awk script? How could I generate both failure.dat and success.dat inside if/else statement?

Thank you for your help.

Both your commands are invalid -- as shown, they have unbalanced 'quotes. Difficult to tell, but you appear to be mixing awk and shell syntax. In awk, (unquoted) failure, success and dat are (undefined) variables, not strings. I suspect awk is throwing syntax on the dot, or possibly even fatal: cannot redirect to . : Is a directory. — Paul_Pedant
– Paul_Pedant, Commented Feb 21 at 16:56
Get used to copy/pasting your shell commands into shellcheck.net until you get more familiar with Unix. — Ed Morton
– Ed Morton, Commented Feb 21 at 22:06

Gilles Quénot · Accepted Answer · 2025-02-22 18:20:42Z

8

You need to quote the filenames to prevent awk to treat them as variables:

awk '{
    if ($NF>=400) {print > "failure.dat"}
    else {print > "success.dat"}
}' file

and you need to do the redirection inside the curly brackets.

You could also shorten it by using the ternary operator:

awk '{print > (($NF < 400 ? "success" : "failure")".dat")}'

(The outer parenthesis is needed in some awk implementations).

edited Feb 22 at 18:20

answered Feb 21 at 16:32

Gilles Quénot

36.8k7 gold badges76 silver badges97 bronze badges

1

@STerliakov, my bad, there was a missing ) indeed.

Stéphane Chazelas
– Stéphane Chazelas

2025-02-22 16:42:40 +00:00
Commented Feb 22 at 16:42

Add a comment |

Paul_Pedant · Accepted Answer · 2025-02-21 17:09:07Z

5

Even clearer:

awk -v Ok=success.dat -v No=failure.dat '{ print > ($NF>=400 ? No : Ok) }' access.dat

answered Feb 21 at 17:09

Paul_Pedant

9,4143 gold badges24 silver badges27 bronze badges

Add a comment |

terdon · Accepted Answer · 2025-02-21 20:56:55Z

4

Your syntax is odd. I don't understand why you have the > outside the { } block. This is a more natural (IMO, anyway) way of writing it:

awk '{if ($NF>=400) print > "failure.dat"; else print > "success.dat"}' access.dat

Or, a bit more clearly:

awk '
{ 
  if ($NF>=400)
    print > "failure.dat"
   
  else
    print > "success.dat"
}' access.dat

And, just for fun, less clearly but more concisely:

awk '{k = $NF>=400 ? "failure.dat" : "success.dat"; print > k}' access.dat

edited Feb 21 at 20:56

answered Feb 21 at 16:38

terdon♦

253k69 gold badges481 silver badges719 bronze badges

Add a comment |

Stack Exchange Network

How to generate two output files from if/else statement by using awk?

3 Answers 3

You must log in to answer this question.

Hot Network Questions

How to generate two output files from if/else statement by using awk?

3 Answers 3

You must log in to answer this question.

Related

Hot Network Questions