How can I generate 10 visually distinct random colors in Delphi FMX?

Question

I'm working on a Delphi FMX project where I need to generate a set of 10 random colors for use in a UI. The problem is that when I use TAlphaColorRec with random RGB values, many of the colors end up looking too similar.

For example, multiple shades of blue or green that are hard to tell apart.

This is my current code that generates the numbers:

function GenerateRandomColors(Count: UInt64): TArray<TAlphaColor>;
begin
  SetLength(Result, Count);
  for var i := 1 to Count do
  begin
    var C: TAlphaColorRec;
    C.R := Random(256);
    C.G := Random(256);
    C.B := Random(256);
    C.A := 255;
    Result[i-1] := C.Color;
  end;
end;

And I'm using it within this procedure:

procedure TForm1.GenerateColors;
begin
  Randomize;

  Memo1.Lines.Clear;
  GridLayout1.DeleteChildren;

  var Colors := GenerateRandomColors(10);
  for var Col in Colors do
  begin
    Memo1.Lines.Add(AlphaColorToString(Col));

    var Rect := TRectangle.Create(GridLayout1);
    Rect.Parent := GridLayout1;
    Rect.Fill.Color := Col;
    Rect.Stroke.Kind := TBrushKind.None;
  end;
end;

And this is how it looks:

I need to modify GenerateRandomColors so that it generates colors that are more visually distinct from each other.

I have looked at the following questions already:

But the answers are not super useful because I need it to work with the Delphi Programming Language and most of those answers are using other programming languages.

Can someone please help me to modify GenerateRandomColors so that it generates distinct colors using Delphi within the FireMonkey (FMX) framework.

How to automatically generate N "distinct" colors? may give you an idea for a better algo. — Filburt
– Filburt, Commented Sep 3 at 10:42
Also Algorithm to randomly generate an aesthetically-pleasing color palette — Filburt
– Filburt, Commented Sep 3 at 10:45
So which parts of other languages don't you understand at all? Apart from answers which show that sooner or later you're unable to come up with distinct colors (mostly 30 at max) and you're better with using your own list of colors to pick from. — AmigoJack
– AmigoJack, Commented Sep 6 at 12:29

AmigoJack · Accepted Answer · 2025-09-08 07:07:40Z

3

Rather than using RGB with random digits for all colors, it might be better to use HSL where L and S are fixed values and your 10 colors are offsets from a single random starting point with a minimum distance that you feel is pleasing. You could randomize L and S as well, just watch out for very low or high values which approach black/white.

Use the function System.UIConsts.HSLtoRGB to convert to RGB space. I've used this approach for coloring the slices of a pie chart so that each slice is visually different from its neighbor and it works well.

10 circles with different colors

The sample below is from the fixed function which I had to adjust slightly to reduce dependencies. It adjusts the S & L if it's odd to avoid near colors from being too close as the number of colors increase. The following is a VCL example, remove the AlphaColorToColor for FMX. I wouldn't random every color or you may end up with two being too close to each other. Just random the first one, then continue with an even offset for H wrapping back to 0 if it goes over 1 and adjust S and L appropriately.

uses
  System.UIConsts;

procedure TForm1.GenerateColors;
var
  H : single;
  i : integer;
begin
  SetLength(fColors,10);
  H := 0.0;
  for I := 0 to High(fColors) do
    begin
      if Odd(I) then
        fColors[i] := AlphaColorToColor( HSLtoRGB(H,0.7,0.7) )
      else
        fColors[i] := AlphaColorToColor( HSLtoRGB(H,0.5,0.5) );
      H := H + (1 / Length(fColors));
    end;
end;

edited Sep 8 at 7:07

AmigoJack

6,4232 gold badges19 silver badges36 bronze badges

answered Sep 7 at 15:24

skamradt

15.6k3 gold badges40 silver badges58 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Shaun Roselt Sep 7 at 18:13

@Thanks. This is almost exactly what I need. I'm busy adapting it now. The key was System.UIConsts.HSLtoRGB.

AmigoJack · Accepted Answer · 2025-09-08 07:10:02Z

2

Thanks skamradt for pointing me in the right direction. This is the function I ended up making and using:

uses
  System.UIConsts;

function GenerateRandomDistinctColors(Count: UInt64): TArray<TAlphaColor>;
begin
  SetLength(Result, Count);
  if Count = 0 then Exit;

  var reserved := 0;
  if Count > 0 then
  begin
    Result[reserved] := TAlphaColors.Black;
    Inc(reserved);
  end;
  if Count > 1 then
  begin
    Result[reserved] := TAlphaColors.White;
    Inc(reserved);
  end;
  if Count > 2 then
  begin
    Result[reserved] := TAlphaColors.Gray;
    Inc(reserved);
  end;

  var remain := Count - reserved;
  if remain <= 0 then Exit;

  var baseHue := Random * 360.0;
  var stepHue := 360.0 / remain;

  var j := 0;
  while j < remain do
  begin
    var hue := baseHue + j * stepHue + (Random * 2.0 - 1.0) * (stepHue * 0.08);
    hue := Frac(hue / 360.0) * 360.0;

    var sat := 0.6 + Random * 0.4; // 0.6..1.0
    var light := 0.45 + Random * 0.2; // 0.45..0.65

    Result[reserved + j] := HSLtoRGB(hue / 360.0, sat, light);
    Inc(j);
  end;
end;

It works similar to this answer, but modified to provide a slightly wider ranger of colors.

Here's an example of the colors it generated:

10 squares displaying different colors

They are now much more distinct from each other. 😁

edited Sep 8 at 7:10

AmigoJack

6,4232 gold badges19 silver badges36 bronze badges

answered Sep 7 at 18:25

Shaun Roselt

4,3615 gold badges29 silver badges60 bronze badges

1 Comment

Stefan Glienke Sep 8 at 15:29

This still needs to support different kinds of colorblindness ;)

Collectives™ on Stack Overflow

How can I generate 10 visually distinct random colors in Delphi FMX?

2 Answers 2

1 Comment

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related