Can I reify class methods from within an instance in Template Haskell?

Question

I have a class called Cls. In one of the instances of Cls, in one of the methods, I want to do some code analysis from within template haskell. I have to run a reify to start this inspection. Full files are included below.

class Cls a where
    infixl 6 +.
    (+.) :: Num a => v a -> v a -> v a

newtype Evaluate a = Evaluate a

instance Cls Evaluate where
    (+.) a b = doSomething $(typesOf '(+.)) a b

typesOf :: Name -> Q Exp
typesOf name = do
        _ <- reify name
        -- do something
        [e|["Double", "Int"]|]

However, at $(typesOf '(+.)), I get the following error:

‘+.’ is not in the type environment at a reify
In the untyped splice: $(typesOf '(+.))

If I compare this to, for example, makeLenses in the Control.Lens library, they do a similar thing. There it works. Which leads me to believe that, somehow, the '(+.) resolves to the function in the current instance declaration instead of the '(+.) in the class declaration.

Is this correct? If so, how do I actually use the class method as an argument to template haskell in this instance (no pun intended)?

{-# LANGUAGE TemplateHaskell #-}

module Main where

import Th

class Cls a where
    infixl 6 +.
    (+.) :: Num a => v a -> v a -> v a

newtype Evaluate a = Evaluate a

instance Cls Evaluate where
    (+.) a b = doSomething $(typesOf '(+.)) a b

-- Below here is not important
doSomething :: [String] -> a -> a
doSomething types a _ = trace (intercalate ", " types) a

main :: IO ()
main = putStrLn "Hello, Haskell!"

{-# LANGUAGE TemplateHaskell #-}

module Th where

import Language.Haskell.TH

typesOf :: Name -> Q Exp
typesOf name = do
        _ <- reify name
        -- do something
        [e|["a", "b"]|]

Noughtmare · Accepted Answer · 2025-08-17 20:25:12Z

7

The problem is that (.+) is in the same declaration group as your splice. Names from the same declaration group are not visible to reify:

Accordingly, the type environment seen by reify includes all the top-level declarations up to the end of the immediately preceding declaration group, but no more.

You can split up declaration groups in several ways. For example you could move the class Cls ... declaration to another module. But perhaps the simplest way is to insert a $(pure []) top level splice between the class declaration and your splice like so:

class Cls a where
    infixl 6 +.
    (+.) :: Num a => v a -> v a -> v a

$(pure [])

instance Cls Evaluate where
    (+.) a b = doSomething $(typesOf '(+.)) a b

As Carl suggests, there is a function newDeclarationGroup in the template-haskell library that gives this pattern a more understandable name. You can use it like this:

class Cls a where
    infixl 6 +.
    (+.) :: Num a => v a -> v a -> v a

$(newDeclarationGroup)

instance Cls Evaluate where
    (+.) a b = doSomething $(typesOf '(+.)) a b

edited Aug 17 at 20:25

answered Aug 15 at 12:47

Noughtmare

11.3k1 gold badge18 silver badges43 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Niek Janssen Aug 15 at 12:54

Fantastic, that is an even easier fix then I was expecting. I didn't know that declaration groups would be so large, I thought they would implicitly be split after each top-level declaration. Thanks :)

Carl Aug 17 at 18:59

Note that the docs suggest using hackage-content.haskell.org/package/template-haskell-2.23.0.0/… for this purpose. It has no different functionality, but it's a standardized name to indicate the purpose of the splice.

Collectives™ on Stack Overflow

Can I reify class methods from within an instance in Template Haskell?

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related