VBA userform with interactive, editable pop-up to view and edit textbox

Question

I have userform1 with a textbox1 and space on the form is limited. I am trying to create an interactive/editable 'pop-up' to give the user a larger space to enter/edit text in textbox1. I created a mini userform2 with textbox2. I added a small commandbutton1 to userform1 that opens userform2, which works fine. I want textbox1 and textbox2 to mirror each other. As text is added/deleted/edited in one, the same occurs in the other. I thought this would be easy, but I can't even get text from textbox1 to appear in textbox2. Here is what I've tried

Private Sub commandbutton1_Click() 'userform1 module
    Dim n As userform2
    Set n = New userform2
    n.Show 'works
    userform2.textbox2.Text = userform1.textbox1.Text 'not working
End Sub

Private Sub Userform_Initialize() 'userform2 module
    userform2.textbox2.Text = userform1.textbox1.Text 'not working
End Sub

Private Sub textbox2_Change() 'tried in userform1 and userform2 modules
    userform1.textbox1.Text = userform2.textbox2.Text 'not working
End Sub

Private Sub textbox1_Change() 'tried in userform1 and userform2 modules
    userform2.textbox2.Text = userform1.textbox1.Text 'not working
End Sub

EDITED

Userform1 contains textbox1 and commandbutton1

Userform2 contains textbox2

I was able to get textbox2 to match textbox1, but not the other way around. Also, I'm not able to keep userform2 in front. For example, if I 'touch' or 'click' on userform1, userform2 disappears behind userform1.

'code in userform1 module
Private Sub commandbutton1_Click()
    Dim N As userform2
    Set N = New userform2
    N.Show
 End Sub

Private Sub textbox1_Change() 'Works! If I type in textbox1
    userform2.textbox2.Text = Me.textbox1.Text
End Sub

'code in userform 2 module. Not able to keep userform2 in front of userform1 if I 'touch' or 'click' on userform1
Private Sub UserForm_Initialize()
    Me.textbox2.Text = userform1.textbox1.Text
    Me.StartUpPosition = 0
    Me.Left = Application.Left + (0.5 * Application.Width) - (0.5 * Width)
    Me.Top = Application.Top + (0.5 * Application.Height) - (0.5 * Height)
End Sub

Private Sub textbox2_Change() 'If I type in textbox2, it does NOT appear in textbox1
    userform1.textbox1.Text = Me.textbox2.Text
End Sub

BobS · Accepted Answer · 2024-12-27 22:01:28Z

0

The following code applies to two userforms, each containing a textbox. The user can type text into either userform/textbox and it will be reflected in the other userform/textbox. You can take this example and adapt it to your needs.

ThisWorkbook module (optional - used just to get the show on the road):

Option Explicit

Private Sub Workbook_Open()
  Call UserForm1.Show
End Sub

Userform1 module code:

Option Explicit

Private Sub commandbutton1_Click()
'    Dim N As UserForm2       >> Do not create a new instance
'    Set N = New UserForm2    >> of Userform2
    UserForm2.Show
 End Sub

Private Sub textbox1_Change()
    UserForm2.TextBox2.Text = Me.TextBox1.Text
End Sub

Userform2 module code:

Option Explicit

Private Sub UserForm_Initialize()
  'Me.StartUpPosition = 0  >>Do NOT set this programmatically - set property at design time

  ' Position Userform2 to the right of Userform1
  UserForm2.Left = UserForm1.Left + UserForm1.Width
  UserForm2.Top = UserForm1.Top
End Sub

Private Sub textbox2_Change()
  UserForm1.TextBox1.Text = Me.TextBox2.Text
End Sub

Userform1 and Userform2 need the following property set:
ShowModal: False
StartUpPosition: 0 - Manual (optional for Userform1)

Textboxes in both userforms need the following properties set:
EnterKeyBehaviour: True
Multiline: True

edited Dec 27, 2024 at 22:01

answered Dec 20, 2024 at 21:51

BobS

8133 silver badges9 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

Yodelayheewho Dec 23, 2024 at 17:07

Thank you for your response. I have a command button on the worksheet to open Userform1, so I skipped your first block of code: Private Sub Workbook_Open. With that said, I'm not able to get this to work.

BobS Dec 26, 2024 at 21:38

You don't really say what isn't working. It works fine for me using your scenario. The only thing I can think of is that Userform2 opens directly on top of Userform1 and you just need to drag Userform2 off to the side a bit to expose Userform1 underneath.

Yodelayheewho Dec 27, 2024 at 14:35

please see the edits above. I hope I've done a better job of explaining. Thank you so much for your willingness to help me.

BobS Dec 27, 2024 at 22:12

Glad to help. There were two main issues with your code: 1. You should not have created a new instance of Userform2. That changed all your references to the Userform2 object which was never opened. The reference to the object that was opened was actually 'N'. 2. StartupPosition property needs to be set at design time. I have updated my answer accordingly. This should now get you moving forward.

Yodelayheewho Jan 9 at 21:16

sorry about the delayed response. Userform1 is large, it nearly fills my screen. Is there a way to 'force' Userform2 to remain visible until I close it vs dragging? Also, typing in Textbox1 shows perfectly in Textbox2, but typing in Textbox2 does not show up in Textbox1.

BobS · Accepted Answer · 2025-01-11 23:26:12Z

I have added another answer here so that you can see the difference between the two.

You can force Userform2 to stay on top of all other userforms by setting the ShowModal property to True. You will need to provide a command button to close the form. You will also not be able to access any controls on Userform1, including textboxes, until you close Userform2. You probably need to reassess your requirements. Do you really need to be able to type in either textbox and have that text appear in the other immediately? Maybe a better approach would be to open Userform2 as modal with any text already entered in Userform1, allow the user to type whatever text they need, and then copy that text back to the textbox on Userform1 when you close Userform2. The code below will do that for you. You need to add a command button to Userform2 and name it pbCloseForm. Due to your lack of screen real estate, I have also adjusted the Userform2 positioning code to open Userform2 to the right of the Textbox on Useform1.

Code for Userform1:

Option Explicit

Private Sub CommandButton1_Click()
  UserForm2.Show
End Sub

Code for Userform2:

Option Explicit

Private Sub pbCloseForm_Click()

  ' Put Userform2 text back into Userform1
  UserForm1.TextBox1.Value = UserForm2.TextBox2.Value

  ' Hide Userform2
  UserForm2.Hide

End Sub

Private Sub UserForm_Activate()

  ' Copy Userform1 text to Userform2
  UserForm2.TextBox2.Value = UserForm1.TextBox1.Value

  ' Position Userform2 to the right of Userform1 Text box
  UserForm2.Left = UserForm1.Left + UserForm1.TextBox1.Left + UserForm1.TextBox1.Width
  UserForm2.Top = UserForm1.Top + UserForm1.TextBox1.Top

End Sub

Collectives™ on Stack Overflow

VBA userform with interactive, editable pop-up to view and edit textbox

2 Answers 2

5 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

5 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related