Use string in another sub

Question

I am aware I'm not the first to have this question. Still I cannot find the solution. I have some vba code for my solidworks, that works fine. However, I want to use a string that I defined in one sub, in another sub. This seems harder than I thought.

My code - simplified:

Public FolderName As String
Public Sub SaveFiles()
   FolderName = "SOLID"  
End Sub

Public Sub UserInput(Parameter1, Parameter2, Parameter3...as string) 'A lot of input from a userform
  For i = LBound(ArrayList) To UBound(ArrayList)
    Debug.Print "FolderName = ", FolderName 'THIS PRINTS EMPTY AND I WANT IT TO PRINT "SOLID"
  Next
End Sub

I use public subs and a public string. I cannot add FolderName to Sub UserInput(FolderName), because then I get the compile error "Argument not optional" for my Call UserInput() that is written in my Userform

What can I do to solve this?

SaveFiles() must run before UserInput() in order for FolderName to be populated with "SOLID". We need to see the part of your code that calls these subs. — Bart McEndree
– Bart McEndree, Commented Oct 8, 2024 at 12:46
@BartMcEndree I'm not sure if I explain it correctly. SaveFiles opens my userform with UserForm.Show. Then the end of my Userform calls Call UserInput(...) — JetskiS
– JetskiS, Commented Oct 8, 2024 at 12:49

user27589787 · Accepted Answer · 2024-10-08 21:02:30Z

1

Public Sub UserInput(ParameterX As String, Optional FolderName As String = "a better default")

  doTheThings
End Sub

edited Oct 8, 2024 at 21:02

answered Oct 8, 2024 at 14:10

user27589787

262 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Black cat Over a year ago

Optional argument can get a default value in the declaration part. like this Optional FolderName As String = "some default" no need the IF...End If

Mark Rotteveel Over a year ago

Although this code might answer the question, I recommend that you also provide an explanation what your code does and how it solves the problem of the question. Answers with an explanation are usually more helpful and of better quality, and are more likely to attract upvotes.

VBasic2008 · Accepted Answer · 2024-10-08 17:33:22Z

Passing Strings to Another Sub

The Calling Procedure

Public Sub SaveFiles()
    
    Dim FolderName As String: FolderName = "SOLID"
    
    ' Using a Parameter Array (Multiple Arguments)
    UserInput FolderName
    UserInput "Solid1", "Solid2", "Solid3"
    
    ' Using an Array (Allowing a Simple Value)
    UserInputArray "Solid4"
    UserInputArray Array("Solid5", "Solid6", "Solid7")
    
    ' Using a Delimited String
    UserInputString "Solid8" ' , ", " ' default
    UserInputString "Solid9, Solid10, Solid11" ' , ", " ' default
 
End Sub

Using a Parameter Array (Multiple Arguments)

Public Sub UserInput(ParamArray FolderNames() As Variant)
    Dim i As Long
    For i = LBound(FolderNames) To UBound(FolderNames)
        Debug.Print "FolderName = " & FolderNames(i)
    Next i
End Sub

Using an Array (Allowing a Simple Value)

Public Sub UserInputArray(FolderNames As Variant)
    If IsArray(FolderNames) Then
        Dim i As Long
        For i = LBound(FolderNames) To UBound(FolderNames)
            Debug.Print "FolderName = " & FolderNames(i)
        Next i
    Else
        Debug.Print "FolderName = " & FolderNames
    End If
End Sub

Using a Delimited String

Public Sub UserInputString( _
        ByVal FoldersString As String, _
        Optional ByVal Delimiter As String = ", ")
    Dim FolderNames() As String: FolderNames = Split(FoldersString, Delimiter)
    Dim i As Long
    For i = 0 To UBound(FolderNames)
        Debug.Print "FolderName = " & FolderNames(i)
    Next i
End Sub

Collectives™ on Stack Overflow

Use string in another sub

2 Answers 2

2 Comments

Passing Strings to Another Sub

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Passing Strings to Another Sub

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related