How does the ms_abi pass between c and assembely

Question

I am working on an OS using EFI using the ms_abi and was wondering how does it pass arguments because I am moving some systemtable info into a register but when I try to call a function using the correct offset it freezes. I think this is because of a incorrect use of the ABI.

I tried using what is on Wikipedia but I don't think it was working. It could be that I am not using the ABI correctly. I tried using RCX and RDX but those are not working. I also looked at the GCC documentation but that was no help either.

This is what i am trying

    .intel_syntax noprefix
    .global efimain 

efimain:
    mov [systable],rcx 
    mov rax,[systable + 40h] 
    mov rax, [rax+18h] 
    mov  rdx,Msg 
    call rax
    mov rax, 0 
    ret

systable: 
    .byte 122 
Msg:
    .word 'H'

I assume from the code you are trying to use OutputString on the Simple Text Output Interface? — Michael Petch
– Michael Petch, Commented May 30, 2024 at 21:15

prl · Accepted Answer · 2024-07-13 02:01:08Z

4

Several things wrong here.

The MS ABI requires 20h bytes of unused space at the top of the stack before the call. (In the called function, this space is just above the return address.)
The stack must be aligned to a multiple of 10h before the call.
The system table is the second parameter to efimain. It is a pointer. To access a field in the system table, you have to use the pointer.
The location where you store the system table pointer must be a qword, not a byte.
The address of the protocol must be passed as the first parameter to OutputString.
The offset of OutputString is 8.
The address of Msg should be loaded using RIP-relative addressing.

The string passed to OutputString must be null-terminated.

     .intel_syntax noprefix
     .global efimain 

 efimain:
     sub rsp, 28h
     mov [rip+systable],rdx 
     mov rcx,[rdx+40h]
     lea rdx,[rip+Msg]
     call [rcx+08h]
     mov rax, 0
     add rsp, 28h
     ret

 systable: 
     .quad 0
 Msg:
     .word 'H',10,0

edited Jul 13, 2024 at 2:01

answered May 30, 2024 at 23:06

prl

12.5k2 gold badges16 silver badges37 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

David Wohlferd Over a year ago

Just to add, ms docs their x64 calling convention here.

lucas Over a year ago

It did not work

fpmurphy Over a year ago

See section 2.3.4 of the UEFI Specification for the X64 platform callling convention.

Stephen Ostermiller · Accepted Answer · 2024-07-13 09:15:36Z

0

I consulted section 2.3.4 of the UEFI Specification for the X64 platform calling convention as suggested by fpmurphy in the comments. It turned out I was wrong. rdx is the systemtable and rcx is the ImageHandle.

edited Jul 13, 2024 at 9:15

Stephen Ostermiller♦

25.8k18 gold badges96 silver badges117 bronze badges

answered Jul 10, 2024 at 17:09

lucas

294 bronze badges

Collectives™ on Stack Overflow

How does the ms_abi pass between c and assembely

2 Answers 2

3 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related