ABAP flag duplicate values in internal table

Question

I need to flag the duplicate values and I found a solution using the code below:

sort result_package stable by knumh zzklfn1.
data lv_prev_knumh type c length 10.

loop at result_package assigning <result_fields>.
  if <result_fields>-knumh <> lv_prev_knumh.
    lv_prev_knumh = <result_fields>-knumh.
    <result_fields>-zzstafkz = ''.
  else.
    <result_fields>-zzstafkz = 'X'.
  endif.
endloop.

But obviously the first duplicated value is not flagged. Output is shown below:

knumh	zzstafkz
001
002
002	x
002	x
003

I don't know really what should I do next.

Why do you need to find duplicates, what do you want to do with them? If you mark all the same records as duplicates it would be logically the same as no records are marked at all, and is totally meaningless. Please clarify your target. — AlexSchell
– AlexSchell, Commented Jun 13, 2023 at 13:53
Your question doesn't seem to be tightly coupled to SAP BW, it just seems an issue with algorithm (and then possibly an ABAP question): if you detect that a line has same KNUMH as previous line, you should set ZZSTAFKZ = 'X' on the previous line too. Simple as that. If you don't know how to update a line at a given index, please ask it. See how to ask. — Sandra Rossi
– Sandra Rossi, Commented Jun 13, 2023 at 15:55
This question is similar to: Finding duplicates in ABAP internal table via grouping. If you believe it’s different, please edit the question, make it clear how it’s different and/or how the answers on that question are not helpful for your problem. — Suncatcher
– Suncatcher, Commented Jul 15, 2024 at 4:44

AlexSchell · Accepted Answer · 2023-06-22 12:50:26Z

1

You can simply do it by keeping the reference to the previous record and assign X flag when the condition meets.

Types declaration and sample data for test:

TYPES: BEGIN OF ty_result_package,
         knumh    TYPE knumh,
         zzstafkz TYPE flag,
       END OF ty_result_package,
       ty_t_result_package TYPE STANDARD TABLE OF ty_result_package
                           WITH DEFAULT KEY.

DATA(lt_result_package) = VALUE ty_t_result_package(
    ( knumh = '001'  )
    ( knumh = '002'  ) ( knumh = '002'  ) ( knumh = '002'  )
    ( knumh = '003'  )
    ( knumh = '004'  ) ( knumh = '004'  ) ).

The logic itself:

FIELD-SYMBOLS: <fs_result_package_prev> type ty_result_package.

SORT lt_result_package BY knumh ASCENDING.
LOOP AT lt_result_package ASSIGNING FIELD-SYMBOL(<fs_result_package>).
  IF <fs_result_package_prev> IS ASSIGNED AND
     <fs_result_package>-knumh = <fs_result_package_prev>-knumh.

    <fs_result_package_prev>-zzstafkz = <fs_result_package>-zzstafkz = 'X'.
  ELSE.
    CLEAR <fs_result_package>-zzstafkz.  " clear the flag if necessary
  ENDIF.

  ASSIGN <fs_result_package> TO <fs_result_package_prev>.
ENDLOOP.

Sample output:

cl_demo_output=>display_data( EXPORTING value = lt_result_package ).

edited Jun 22, 2023 at 12:50

answered Jun 13, 2023 at 22:20

AlexSchell

1,7051 gold badge4 silver badges24 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Philipp Over a year ago

Note that this only works if the table is sorted by the field(s) you are checking to identify duplicates.

AlexSchell Over a year ago

Correct, added the additional sort statement in order this requirement would not be overlooked.

Collectives™ on Stack Overflow

ABAP flag duplicate values in internal table

1 Answer 1

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related