Applescript code breaking when removing trailing spaces

I'm a bit late coming in on this. Ted Wrigley has his eye on the ball, noticing, quite rightly, that the neatest and most efficient solution is by way of text item delimiters. I defer credit to him for providing, in my view, the most suitable answer offered thus far, to which this is essentially just a follow-up to illustrate that one can achieve identical results with a much more compact, two-line handler:

to removeAllWhitespace from input as text
    set text item delimiters to {pi, space, tab, linefeed, return}
    return the input's text items as text
end removeAllWhitespace

I also took the liberty of having it clear out all (traditional) whitespace characters besides space, i.e. tab characters, and new-line characters too. You can probably deduce how to remove those options if you so wished.

To call the handler:

removeAllWhitespace from "   spa     .          nish  . txt  "

which outputs: "spa.nish.txt"

Huh? Pi...?

In short: Pick anything random that isn't text and is unlikely to appear in a filename. If in doubt: use pi ^ pi.

In detail: _{Don't be too bogged down by it being pi: the use of pi in the list of delimiters above holds no significance in and of itself as a quantity, and the only function it serves is as a non-string entity that allows all of the delimiters in the list to be removed from the filename, which will include any occurrences of itself in string-form, i.e. "3.14159265359". Provided this sequence of characters doesn't appear in a filename, pi is likely a good choice to serve as this "dummy delimiter". Otherwise, the key is to swap out pi for any other non-string value. Say... pi + 1 ? I often use null, missing value, or a randomly-generated number. But, if ever you find you can't be bothered to generate a number or think of one yourself, just use pi ^ pi.}

The direct answer to your question is the you shouldn't use 'end' in this context, but use '-1' to indicate the last character, '-2' to indicate the second to last character, etc. The result would end up looking like this:

on stripSpaces(thisText)
    local newText
    local pos
    local tempText

    set newText to thisText

    set tempText to ""

    repeat while tempText ≠ newText
        set tempText to newText

        --remove spaces before extension name
        set pos to the offset of ". " in newText

        if pos > 0 then
            set newText to ((characters 1 thru pos of newText) as text) & (characters (pos + 2) thru -1 of newText) as text
        end if

        --remove spaces before extension
        set pos to the offset of " ." in newText

        if pos > 0 then
            set newText to ((characters 1 thru (pos - 1) of newText) as text) & (characters (pos + 1) thru -1 of newText) as text
        end if

        --remove leading spaces
        if character 1 of newText = " " then
            set newText to characters 2 thru -1 of newText as text
        end if

        ---BROKEN SECTION

        --remove trailing spaces
        if (last character of newText) = " " then
            set newText to (characters 1 thru -2 of newText) as text
        end if
    end repeat

    return newText
end stripSpaces

log stripSpaces("   spa     .          nish  . txt  ")

However, if you goal is simply to strip spaces, you can do that a lot more efficiently using text item delimiters:

on stripSpaces(thisText)
    set tid to my text item delimiters
    set my text item delimiters to " "  -- break text at spaces
    set textParts to text items of thisText
    set my text item delimiters to ""  -- recombine text without spaces
    set strippedText to textParts as text
    set my text item delimiters to tid
    return strippedText
end stripSpaces

log stripSpaces("   spa     .          nish  . txt  ")