How to create an alias for a command in Vim?

Question

Vim is my preferred text editor when I program, and thus I always run into a particularly annoying issue.

Frequently, when I quickly need to save the buffer and continue on to some other miscellaneous task, I do the typical

:w

However, I always — what seems to be like more than 50% of the time — manage to capitalize that :w. Naturally, Vim yells at me because W is an invalid command:

E492: Not an editor command: W

My question is how can one alias colon-commands in Vim. Particularly, could you exemplify how to alias W to w.

I am aware of the process to map keys to certain commands, but that is not what I’m looking for.

To avoid :W you could a map a key to perform the saving. If you are used to some program that saves with Ctrl-s, there are these mappings from $VIM/mswin.vim: " Use CTRL-S for saving, also in Insert mode noremap <C-S> :update<CR> vnoremap <C-S> <C-C>:update<CR> inoremap <C-S> <C-O>:update<CR> — mMontu
– mMontu, Commented May 23, 2012 at 14:21
Similar question on Vi Stack exchange: vi.stackexchange.com/q/2665/7244 — Flimm
– Flimm, Commented Aug 24, 2018 at 12:23

I.B. · Accepted Answer · 2020-09-26 05:32:59Z

161

To leave completion untouched, try using

cnoreabbrev W w

It will replace W in command line with w, but only if it is neither followed nor preceded by word character, so :W<CR> will be replaced with :w<CR>, but :Write won’t. (Note that this affects any commands that match, including ones that you might not expect. For example, the command :saveas W Z will be replaced by :saveas w Z, so be careful with this.)

Update

Here is how I would write it now:

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

As a function:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

This checks that the command type is : and the command is W, so it’s safer than just cnoreabbrev W w.

edited Sep 26, 2020 at 5:32

I.B.

29.2k13 gold badges87 silver badges108 bronze badges

answered Oct 7, 2010 at 8:03

ZyX

53.9k7 gold badges120 silver badges138 bronze badges

Sign up to request clarification or add additional context in comments.

17 Comments

Sean Over a year ago

This answer is the safest and most reliable for me.

cprn Over a year ago

If you use the recommended solution, please, be aware both of the two below commands will work as the lower one which may present an unexpected result depending on the actual buffer content and VIM settings: :%s/W/foo/g<CR> :%s/w/foo/g<CR>

airstrike Over a year ago

Actually, this would mean W will be replaced anywhere in the command bar, including, for example, in searches, so s/W foo/bar/g would be turned into s/w foo/bar/g. this can get annoying really fast. see my answer for a comprehensive solution.

Chris Morgan Over a year ago

Absolutely; this is a horrible idea. You should never, ever, ever do this.

kev Over a year ago

:cnoreabbrev <expr> W getcmdtype()==':'&&getcmdline()=~#'^W'?'w':'W'

|

Community · Accepted Answer · 2017-05-23 11:47:20Z

121

With supplementary searching, I've found that someone asked nearly the same question as I.

:command <AliasName> <string of command to be aliased>

will do the trick.

Please be aware that, as Richo points out, the user command must begin with a capital letter.

edited May 23, 2017 at 11:47

CommunityBot

11 silver badge

answered Oct 7, 2010 at 4:34

Sean

5,4235 gold badges25 silver badges26 bronze badges

5 Comments

Pavel Strakhov Over a year ago

Using :command is good solution. :cnoreabbrev doesn't understand cmd1|cmd2, :command does.

Alec Jacobson Over a year ago

A less confusing way to write this is, :command AliasName string of command to be aliased

blueyed Over a year ago

This won't handle/forward any command arguments, like -nargs, -complete etc.

Jacklynn Over a year ago

What about :Q! or :W!?

isomorphismes Over a year ago

Just to be very literal: put :command W w in the .vimrc file.

fent · Accepted Answer · 2014-02-13 17:50:41Z

28

I find that mapping the ; key to : would be a better solution, and would make you more productive for typing other commands.

nnoremap ; :
vnoremap ; :

answered Feb 13, 2014 at 17:50

fent

18.3k16 gold badges91 silver badges91 bronze badges

7 Comments

airstrike Over a year ago

This is the single best tip for vim. I'm so used to it now that every time I encounter the normal behavior, it takes me a few tried to get my mind retrained.

Flimm Over a year ago

This is not an answer to the question.

Dessa Simpson Over a year ago

@Flimm No, but it makes OP's issue go away.

Luc Over a year ago

When using t or f, one can usually use ; to go to the next occurrence. One can safely map that the other way, even if you mapped semicolon to colon. There won't be an alias loop. nnoremap : ;

Dessa Simpson Over a year ago

@EricDuminil If you go from : to ;, then you're no longer using shift when typing ;w and therefore won't accidentally type W instead of w.

|

jdhao · Accepted Answer · 2020-09-27 11:32:07Z

13

The best solution involves writing a custom function for handling abbreviations that only take place in the beginning of the command bar.

For this, add the following your vimrc file or anywhere else.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

A few useful abbreviations from the source material where I found this stuff:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

edited Sep 27, 2020 at 11:32

jdhao

29.5k23 gold badges159 silver badges323 bronze badges

answered May 22, 2012 at 19:22

airstrike

2,4211 gold badge27 silver badges28 bronze badges

2 Comments

ZyX Over a year ago

There is a built-in function string() that does the same thing as yours Single_quote().

Jacktose May 23 at 23:38

But don't you have to type <c-]>, space, or some other non-keyword character after abbreviations? So I'd end up typing :s/<c-]> or :s/ <bs>, which hardly seems faster.

Andrew Barber · Accepted Answer · 2013-02-27 05:20:50Z

7

Suppose you want to add alias for tabnew command in gvim. you can simply type the following command in your .vimrc file (if not in home folder than create one)

cabbrev t tabnew

edited Feb 27, 2013 at 5:20

Andrew Barber

40.3k20 gold badges97 silver badges124 bronze badges

answered Feb 27, 2013 at 3:46

Sandip

791 silver badge1 bronze badge

1 Comment

Flimm Over a year ago

This will cause a command like :saveas t example to be replaced with :saveas tabnew example

Benoit · Accepted Answer · 2010-10-07 06:36:10Z

5

Maybe you would like to map one of your function keys (F1..F12) to :w ? Then put this into your .vimrc:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(ctrl-o in insert mode switches temporarily to normal mode).

answered Oct 7, 2010 at 6:36

Benoit

79.7k24 gold badges226 silver badges241 bronze badges

Comments

Enno · Accepted Answer · 2016-04-11 17:45:57Z

5

Safest and easiest is a plugin such as cmdalias.vim or my recent update vim-alias of it that take into account

preceding blanks or modifiers such as :sil(ent)(!) or :redi(r),
range modifiers such as '<,'> for the current visual selection,
escape special characters such as quotes, and
check if the chosen alias is a valid command line abbreviation.

answered Apr 11, 2016 at 17:45

Enno

2582 silver badges6 bronze badges

Comments

achalk · Accepted Answer · 2021-11-13 03:13:01Z

I think @ZyX's answer is great, but if you're using a newer version of neovim (0.5+), you might want to define the function using lua instead. Here's one way you could do it:

function _G.abbreviate_or_noop(input, output)
  local cmdtype = vim.fn.getcmdtype()
  local cmdline = vim.fn.getcmdline()

  if (cmdtype == ":" and cmdline == input) then 
    return output
  else
    return input
  end
end

function SetupCommandAlias(input, output)
  vim.api.nvim_command("cabbrev <expr> " .. input .. " " .. "v:lua.abbreviate_or_noop('" .. input .. "', '" .. output .. "')")
end

Then, you'd drop the call from call SetupCommandAlias("pg", "postgres://") and just use the function like this: SetupCommandAlias("pg", "postgres://").

n.b. If using it from a .vim file instead of a .lua file, you'd need to prefix the function call with lua, i.e. lua SetupCommandAlias("pg", "postgres://").

Collectives™ on Stack Overflow

How to create an alias for a command in Vim?

8 Answers 8

Update

17 Comments

5 Comments

7 Comments

2 Comments

1 Comment

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

8 Answers 8

Update

17 Comments

5 Comments

7 Comments

2 Comments

1 Comment

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related