How to loop over environment variables in windows batch file? [duplicate]

Question

In windows, I want to loop over a set of environment variables like in this pseudo code:

set MYVAR1=test
set MYVAR2=4711
set MYVAR3="a b c"

for /l %%x in (1, 1, 3) do (
   echo %MYVAR%s%%
)

for which I expect the following output

test
4711
a b c

How to change this example code to get it to work?

I suggest you to review this post

Aacini
– Aacini

2014-07-23 13:43:50 +00:00
Commented Jul 23, 2014 at 13:43 — Aacini
– Aacini, Commented Jul 23, 2014 at 13:43

npocmaka · Accepted Answer · 2014-07-23 11:27:07Z

5

@echo off
set MYVAR1=test
set MYVAR2=4711
set MYVAR3="a b c"

setlocal enableDelayedExpansion
for /l %%x in (1, 1, 3) do (
   echo !MYVAR%%x!
)
endlocal

answered Jul 23, 2014 at 11:27

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Alex Over a year ago

Perfect, it works! Could you recommend a page which describes this strange delayed expansion thing?

npocmaka Over a year ago

here : ss64.com/nt/delayedexpansion.html and here : robvanderwoude.com/variableexpansion.php

MC ND · Accepted Answer · 2014-07-23 12:00:59Z

2

One more way, parse the output of set command using the variable prefix

@echo off
    setlocal enableextensions disabledelayedexpansion

    set MYVAR1=test
    set MYVAR2=4711
    set MYVAR3="a b c"

    for /f "tokens=1,* delims==" %%a in ('set MYVAR') do echo %%b

answered Jul 23, 2014 at 12:00

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

Comments

foxidrive · Accepted Answer · 2014-07-23 11:46:37Z

1

Another method:

@echo off
set MYVAR1=test
set MYVAR2=4711
set MYVAR3="a b c"

for /l %%x in (1, 1, 3) do (
   call echo %%MYVAR%%x%%
)
pause

answered Jul 23, 2014 at 11:46

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

Collectives™ on Stack Overflow

How to loop over environment variables in windows batch file? [duplicate]

3 Answers 3

2 Comments

Comments

Comments

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

Comments

Comments

Linked

Related