5
\$\begingroup\$

I had to come up with a way to convert sqrt(#) into its actual numeric value because before I would have an array containing elements such as:

[sqrt(3), -sqrt(3), 1]

I receive the list of values from Mathematica output in bracket format and do some string manipulation to make it look nicer.

If I tried to multiply, I would get the error:

Argument "-sqrt(3)" isn't numeric in multiplication (*)

Here is my work-around, but I think there's a better way. Any suggestions?

#!/usr/bin/perl
#perl Solver.pl

use strict;
use warnings;


my $roots = "Sqrt[3] ||-Sqrt[3] ||1";
my @rootList = split(/ \|\|/, $roots); # fill array with string's values separated by " ||"


# Convert any Sqrt numbers to numerical value 
# (ex.) Sqrt[3] -> sqrt(3)
for $_ ( @rootList ){
    $_ =~ s/Sqrt\[/sqrt(/g; # Sqrt[ -> sqrt(
    $_ =~ s/\]/)/g; # ] -> )

    if( $_ =~ /-sqrt/ ){ # replace string of negative sqrt()
        my $temp = substr( $_, 6 ); # take "#)"
        $temp =~ s/\)//g; # remove ")"
        $_ = -1*sqrt( $temp );
    }
    elsif( $_ =~ /sqrt/ ){ # replace positive sqrt()
        my $temp = substr( $_, 5 );
        $temp =~ s/\)//g;
        $_ = sqrt( $temp );
    }
}

print "[@rootList]\n";
\$\endgroup\$

2 Answers 2

Reset to default
5
\$\begingroup\$

I found the use of Sqrt[...] to be cumbersome, why have the case in that format, and why have the [] style braces?

I would normally not recommend this, but a simple solution, if you trust, or can sanitize your inputs, is to just use the eval function.

for $_ ( @rootList ){
    $_ =~ s/Sqrt\[(.+)\]/sqrt($1)/;
    $_ = eval($_);
    $@ and die $@;
}

That does it..... all of it. Convert Sqrt[...] to sqrt(...), and eval the result.

\$\endgroup\$
1
  • \$\begingroup\$ I receive the list of values from Mathematica output in bracket format and do some string manipulation to make it look nicer. Thanks! Nice solution. \$\endgroup\$ Commented Jun 10, 2015 at 4:23
2
\$\begingroup\$

It is great that the code uses strict and warnings and has helpful comments.

I'll offer some critique on the code and propose an alternate solution.

From a style perspective, it is common to omit parentheses when using Perl built-in functions like:

split
substr

The following line of code is more commonly written without the $_ variable:

for $_ ( @rootList ){

Similarly, $_ is normally not used with regular expressions or the s/// substitution operator:

$_ =~ s/Sqrt\[/sqrt(/g; # Sqrt[ -> sqrt(

Consider a more flexible approach to the split to account for arbitrary whistespace around the || delimiters:

my @rootList = split /\s*\|\|\s*/, $roots;

Finally, there is no need for all the substitutions when you can simply extract the number using a regular expression. Here is an alternate solution which does not rely on eval:

use strict;
use warnings;

my $roots = "Sqrt[3] ||-Sqrt[3] ||1";
my @rootList = split /\s*\|\|\s*/, $roots; # fill array with string's values separated by " ||"

# Convert any Sqrt numbers to numerical value 
# (ex.) Sqrt[3] -> sqrt(3)
for (@rootList) {
    my $neg = (/-sqrt/i) ? '-': '';
    if (/sqrt\[(\d+)/i) {
        $_ = $neg . sqrt $1;
    }
}

print "[@rootList]\n";
\$\endgroup\$

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.