Search a String array in Delphi

I wrote one I modeled after the old Clipper AScan function (tested in XE). @RRUZ's answer is more correct (there is one existing), but mine doesn't require the array to be sorted first and is fast enough on small arrays. (It also works in pre-generics versions of Delphi.) I also overload it for various types of array - here are the implementations for string and integer:

// Returns the 0-based index of Value if it's found in the array,
// -1 if not. (Similar to TStrings.IndexOf)
function AScan(const Ar: array of string; const Value: string): Integer; overload;
var
  i: Integer;
begin
  Result := -1;
  for i := Low(Ar) to High(Ar) do
    if SameText(Ar[i], Value) then
    begin
      Result := i;
      Break
    end;
end;

function AScan(const Ar: array of Integer; const Value: Integer): Integer; overload;
var
  i: Integer;
begin
  Result := -1;
  for i := Low(Ar) to High(Ar) do
    if (Ar[i] = Value) then
    begin
      Result := i;
      Break
    end;
end;

procedure TForm2.FormShow(Sender: TObject);
var
  someStrArray: TArray<string>;
  someIntArray: TArray<Integer>;
  Idx: Integer;
begin
  someStrArray := TArray<string>.Create('One', 'Two', 'Three');
  Idx := AScan(someStrArray, 'Two');
  if Idx > -1 then
    ShowMessage(Format('It contains Two at index %d', [Idx]))
  else
    ShowMessage('Not found');
  someIntArray := TArray<Integer>.Create(8, 16, 32);
  Idx := AScan(someIntArray, 32);
  if Idx > -1 then
    ShowMessage(Format('It contains 32 at %d', [Idx]))
  else
    ShowMessage('16 not found');
end;

For versions of Delphi that support generics, here's a version that doesn't require the array to be sorted, and that also allows you to provide the comparison function if needed:

Interface:

type
  TGenericsUtils = class
  public
    class function AScan<T>(const Arr: array of T; const Value: T; const Comparer: IEqualityComparer<T>):  Integer; overload;
    class function AScan<T>(const Arr: array of T; const Value: T): Integer; overload;
  end;

Implementation

class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T): Integer;
begin
  Result := AScan<T>(Arr, Value, TEqualityComparer<T>.Default);
end;

class function TGenericsUtils.AScan<T>(const Arr: array of T; const Value: T;
  const Comparer: IEqualityComparer<T>): Integer;
var
  i: Integer;
begin
  for i := Low(Arr) to High(Arr) do
    if Comparer.Equals(Arr[i], Value) then
      Exit(i);
  Exit(-1);
end;

Test code:

var
  AIntTest: TIntegerDynArray;
  AStrTest: TStringDynArray;

begin
  AIntTest := TIntegerDynArray.Create(12, 15, 6, 1, 4, 9, 5);
  AStrTest := TStringDynArray.Create('One', 'Six', 'Three', 'Four', 'Twelve');
  WriteLn('AIntTest contains 9 at index ', TGenericsUtils.AScan<Integer>(AIntTest, 9));
  WriteLn('AStrTest contains ''Four'' at index ', TGenericsUtils.AScan<String>(AStrTest, 'Four'));
  ReadLn;
end.

you can use the TArray.BinarySearch function, which is part of the Generics.Collections unit.

check this sample

{$APPTYPE CONSOLE}

{$R *.res}

uses    
  Generics.Defaults,
  Generics.Collections,
  System.SysUtils;

Var
  someArray: TArray<string>;
  FoundIndex : Integer;

begin
  try
    someArray:=TArray<string>.Create('a','b','c');
    if TArray.BinarySearch<String>(someArray, 'b', FoundIndex, TStringComparer.Ordinal) then
     Writeln(Format('Found in index %d',[FoundIndex]))
    else
     Writeln('Not Found');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

Note: BinarySearch requires that the array be sorted.