Can I modify the Message of a caught Delphi Exception object and then re-raise it?

Question

The title says it, but here is an example:

try
  // ...
  raise EFileNotFoundException.Create('File not found!');
except
  on E: EFileNotFoundException do begin
    E.Message := Format('"%s": %s', ['nonexistent.txt', E.Message]);    // hmm...
    raise;
  end;
end;

Now, there are actually two questions:

This code does compile just fine, but is it guarranteed to do so everytime, i.e., is it documented/non-undefined behavior?
Is it a good practice? If not, what is the proper way to do this?

What I'm trying to do is attach the name of the file which caused the exception, without modyfing the code which raises it.

Answer 1 · 2025-11-19 16:39:44Z

DelphiCoder

• 2 days ago

Looks just as I would have done it.

Answer 2 · 2025-11-19 17:10:30Z

Technically, what you have will work just fine, as the caught Exception is just another object in memory, so you can freely modify it before re-raising it.

However, it is not "best practice" to modify a caught exception. A better option would be to raise a new Exception object that has your desired details in it, and the caught Exception is assigned to the new exception's InnerException property. Use the Exception.RaiseOuterException() method for this purpose, eg:

type
  ECantOpenFileException = class(Exception)
  public
    FileName: string;
    constructor Create(const AFileName: string);
  end;

constructor ECantOpenFileException.Create(const AFileName: string);
begin
  inherited Create('File "' + AFileName + '" could not be opened');
  FileName := AFileName;
end;

...

try
  // ...
  raise EFileNotFoundException.Create('File not found!');
except
  on E: Exception do begin
    Exception.RaiseOuterException(ECantOpenFileException.Create('nonexistent.txt'));
  end;
end;

If a higher exception handler wants to know why you raised an exception, they can walk the exception's InnerException chain to gather those details, eg:

try
  ...
except
  on E: Exception do
  begin
    var Msg := E.Message;
    var innerEx := E.InnerException;
    while innerEx <> nil do begin
      Msg := Msg + #10'  ' + innerEx.Message;
      innerEx := innerEx.InnerException;
    end;
    ShowMessage(Msg);
  end;
end;

Answer 3 · 2025-11-20 16:00:51Z

@MatthiasB your proposed edit to my answer is not necessary. RaiseOuterException() is a class procedure, so it can (and should) be called on the Exception class itself, as I showed. It does not need to be called on the caught Exception object. Internally, it knows what the active Exception object is (via System.ExceptObject), and will capture it into the InnerException of the new Exception object that it is being asked to raise.

Collectives™ on Stack Overflow

Can I modify the Message of a caught Delphi Exception object and then re-raise it?

3 Replies 3

Your Reply

Collectives™ on Stack Overflow

Can I modify the Message of a caught Delphi Exception object and then re-raise it?

3 Replies 3

Your Reply

Sign up or log in

Post as a guest