Lisp: Iterating over slots with a macro

Question

With this:

(defclass test-class ()
  ((data :initarg :data)
   (other :initarg :other)))

(defmethod test ((tc test-class) &key)
  (macrolet ((print-slot (slot)
               `(with-slots (,slot) tc
                  (format t "slot value: ~a~%" ,slot))))
    (print-slot data)
    (print-slot other)))

I can do:

CL-USER> (test (make-instance 'test-class :data "data" :other "other"))
slot value: data
slot value: other

But I can't seem to iterate over them:

(defmethod test ((tc test-class) &key)
  (macrolet ((print-slot (slot)
               `(with-slots (,slot) tc
                  (format t "slot value: ~a~%" ,slot))))
    (dolist (slot '(data other))
      (print-slot slot))))

CL-USER> (test (make-instance 'test-class :data "data" :other "other"))
When attempting to read the slot's value (slot-value), the slot
SLOT is missing from the object #<TEST-CLASS {1001E3FFB3}>.
   [Condition of type SB-PCL::MISSING-SLOT]

Any idea how I can get this effect?

Macros evaluate their arguments at compile time, you can't use a run-time variable for it. — Barmar
– Barmar, Commented May 9 at 14:52

Barmar · Accepted Answer · 2025-05-09 14:55:52Z

3

Use a function, not a macro, so the argument will be evaluated.

(defmethod test ((tc test-class) &key)
  (flet ((print-slot (slot)
           (format t "slot value: ~a~%" (slot-value tc slot))))
    (dolist (slot '(data other))
      (print-slot slot))))

answered May 9 at 14:55

Barmar

789k57 gold badges554 silver badges669 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Ehvince · Accepted Answer · 2025-05-11 20:29:52Z

2

Still without a macro, to iterate on all slots of a given object:

(defclass test-class ()
  ((data :initarg :data)
   (other :initarg :other)))

(defparameter *obj* (make-instance 'test-class :data "foo" :other "bar"))

(dolist (slot (sb-mop:class-slots (class-of *obj*)))
  (format t "this is slot ~a~&" slot))
;; this is slot #<STANDARD-EFFECTIVE-SLOT-DEFINITION DFIO:DATA>
;; this is slot #<STANDARD-EFFECTIVE-SLOT-DEFINITION LS-USER::OTHER>

You can inspect a slot object with describe:

#<SB-MOP:STANDARD-EFFECTIVE-SLOT-DEFINITION DATA>
  [standard-object]

Slots with :INSTANCE allocation:
  SOURCE                         = NIL
  NAME                           = DATA
  INITFORM                       = NIL
  INITFUNCTION                   = NIL
  INITARGS                       = (:DATA)
  %TYPE                          = T
  %DOCUMENTATION                 = NIL
  %CLASS                         = #<STANDARD-CLASS CL-USER::TEST-CLASS>
  ACCESSOR-FLAGS                 = 7
  INFO                           = #S(SB-PCL::SLOT-INFO..
  ALLOCATION                     = :INSTANCE
  ALLOCATION-CLASS               = #<STANDARD-CLASS CL-USER::TEST-CLASS>
  LOCATION                       = 0

and access its metadata with sb-mop:slot-definition-[name, initargs, allocation…]. Get their value with slot-value:

(slot-value *obj* (sb-mop:slot-definition-name slot))

See also class-direct-slots, and use closer-mop for portability.

answered May 11 at 20:29

Ehvince

18.7k8 gold badges64 silver badges84 bronze badges

1 Comment

Gwang-Jin Kim Jun 27 at 8:15

I would say this is the right answer. sb-mop:class-slots lists by introspection the names of the slots over which you can iterate.

Collectives™ on Stack Overflow

Lisp: Iterating over slots with a macro

2 Answers 2

Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related