Adding suffix to duplicate file in Apple Script

Your script doesn't work anyway because the button names don't match and a single quote character is missing in the do shell script line.

Never mind, you need a handler which checks the file name and adds an index.
This is a bit cumbersome because the case no extension must be covered and if there is an extension you have to strip the extension from the file name.

POSIX file choose folder is not needed.
choose folder is sufficient and you can delete the folder keywords.

The only way to move and rename a file simultaneously is with mv of the shell.

(* Version 1.2b
Move to Bin prompt added
Fixed activate Finder
add ability to keep a duplicate *)

on run {input, parameters}
    tell application "Finder"
        set fileToMove to item 1 of input
        set fileName to name of fileToMove
        set fileExtension to name extension of fileToMove ¬
            --gets extension incase file needs to be renamed
        activate
        set chosenFolder to choose folder with prompt "Select a folder to move " & fileName & " "
        log POSIX path of chosenFolder
        
        try
            move fileToMove to chosenFolder
            -- Make sound play only on success
        on error
            -- Display notification with title "File Not Moved" subtitle "File with that name already exists at that location"
            
            display alert "Duplicate File Found" message "Would you like to move " & fileToMove & " to the Bin or Keep & Rename?" buttons {"Move Duplicate to Bin", "Keep & Rename", "Cancel"} default button "Keep & Rename"
            set buttonReturned to button returned of result
            
            if buttonReturned is "Keep & Rename" then
                set newPath to my checkFileName(chosenFolder as text, fileName, fileExtension)
                do shell script "mv " & quoted form of POSIX path of fileToMove & space & quoted form of POSIX path of newPath
                do shell script "afplay '/System/Library/Components/CoreAudio.component/Contents/SharedSupport/SystemSounds/system/Volume Mount.aif'"
            end if
            
            if buttonReturned is "Move Duplicate to Bin" then
                -- Move the file to the trash
                move fileToMove to trash
            end if
        end try
    end tell
end run

-- fDir: HFS path destination folder
-- fName: full file name
-- fExt: name extension

on checkFileName(fDir, fName, fExt)
    if fExt is "" then
        set fullExt to fExt
        set baseName to fName
    else
        set fullExt to "." & fExt
        set endIndex to offset of fullExt in fName
        set baseName to text 1 thru (endIndex - 1) of fName
    end if
    set _index to 0
    repeat
        set _index to _index + 1
        set newPath to (fDir & baseName & "_" & (_index as text) & fullExt)
        try
            newPath as alias
            -- file exists – repeat again
        on error
            -- file does does not exist – return new path
            return newPath
            
        end try
    end repeat
end checkFileName