How to transform a string from a delphi code source into a standard string to be saved in a database?

Question

I've written a parser to extract from my Delphi code, the resourcestring to save them into a database that I should send to a translator.

My request is : Is there an easy way to transform a Delphi string like from source code to a "standard" string ready to be save into database ?

Here is an example : from my source code I have this :

MyResourceString1 = 'Error : I can''t load the file from disk !';

or

MyResourceString2 = 'Error : I can'#39't load the file from disk !';

then after my parser process, I've extracted these kind of string values. But before to save them into a database, I would like to transform all the strings to a "standard" sentence like :

"Error : I can't load the file from disk !"

or

"Error : I can't load the file from disk !"

I would like to use an interpreter function unlike parse the Delphi string to change all #code char to the right char.

Thank you for your help.

Is it ever correct to have a space before a question or exclamation mark? — AmigoJack
– AmigoJack, Commented Jan 25, 2021 at 13:34
If the strings comes from Delphi source code, then there are a lot of possibilities and you need a compiler to be sure to grab everything. Unless the sample you gave is all what there is (simple concatenation of string and character constant). Instead of grabbing from source, you may extract the resource string from the executable where it is in final compiled form. — fpiette
– fpiette, Commented Jan 25, 2021 at 13:55
@AmigoJack : This is exactly why I need to send my french strings to a translator... Thanks for the link — Laurent
– Laurent, Commented Jan 25, 2021 at 13:55
@fpiette : I need to grab from source, because from executable, my resourcestring identifiers become an integer. My Delphi parser extracts resourcestring to transform them in an editable description by a translator and by return, I generate another Delphi unit with the included translations (by the way, I need the identifier name). So what I understand is, I need to replace all unicode integer code (like '#39#') by the right char... — Laurent
– Laurent, Commented Jan 25, 2021 at 14:02
That will not answer your question, but I use dxGetText to translate my applications and all the problem you have and many more are already solved with that tool. There is a tool to scan all source and dfm files to extract strings, resource string and strings in component properties. You get a text file in a specific format. Then there is poEdit application used for the translator. See dxgettext.po.dk/Home — fpiette
– fpiette, Commented Jan 25, 2021 at 14:06

Andreas Rejbrand · Accepted Answer · 2021-01-25 14:14:45Z

This is easy to implement using a simple state machine:

function TryParseStringLiteral(const ALiteral: string; out AString: string): Boolean;
var
  LLiteral: string;
  i, c: Integer;
  InQuotes: Boolean;
  InCharCode: Boolean;
  NumCodeStr: string;
  NumVal: Integer;
begin

  LLiteral := ALiteral.Trim;

  SetLength(AString, LLiteral.Length);

  InQuotes := False;
  InCharCode := False;
  NumCodeStr := '';
  NumVal := 0;
  c := 0;
  for i := 1 to LLiteral.Length do
  begin

    if InCharCode then
    begin
      if (LLiteral[i] = '#') or (LLiteral[i] = '''') then
      begin
        if TryStrToInt(NumCodeStr, NumVal) and InRange(NumVal, Word.MinValue, Word.MaxValue) then
        begin
          Inc(c);
          AString[c] := Chr(NumVal);
        end
        else
          Exit(False);
        InCharCode := LLiteral[i] = '#';
        InQuotes := LLiteral[i] = '''';
        NumCodeStr := '';
        NumVal := 0;
      end
      else
        NumCodeStr := NumCodeStr + LLiteral[i];
    end
    else if InQuotes then
    begin
      if (LLiteral[i] = '''') and (i < LLiteral.Length) and (LLiteral[Succ(i)] = '''') then
      begin
        InQuotes := False; // a bit of a hack
        Inc(c);
        AString[c] := '''';
      end
      else if LLiteral[i] = '''' then
        InQuotes := False
      else
      begin
        Inc(c);
        AString[c] := LLiteral[i];
      end;
    end
    else if LLiteral[i] = '''' then
      InQuotes := True
    else if LLiteral[i] = '#' then
      InCharCode := True
    else
      Exit(False);

  end;

  if InCharCode then
    if TryStrToInt(NumCodeStr, NumVal) and InRange(NumVal, Word.MinValue, Word.MaxValue) then
    begin
      Inc(c);
      AString[c] := Chr(NumVal);
    end
    else
      Exit(False);

  if InQuotes then
    Exit(False);

  SetLength(AString, c);
  Result := True;

end;

To try it:

procedure TForm1.Edit1Change(Sender: TObject);
var
  S: string;
begin
  if TryParseStringLiteral(Edit1.Text, S) then
    Edit2.Text := S
  else
    Edit2.Text := ' -- Invalid string literal -- ';
end;

Some examples:

'This is a test!'                    This is a test!
'What''s up?'                        What's up?
'alpha'#64'beta'#63                  alpha@beta?
'alpha'#$40'beta'#$3F                alpha@beta?
#94#94#94                            ^^^
#94#94#94'ABC'                       ^^^ABC
'ABC'#94#94#94                       ABC^^^
'ABC'#94#94#94'abc'                  ABC^^^abc
'ABC'#94#94#94'abc'#63'!'            ABC^^^abc?!
'test'#32'again'                     test again
'test'#32#32#$20'again'              test   again
''                                   
''''                                 '
''''''''                             '''
'a'                                  a
#65                                  A
#65#$21                              A!
'''test'''#65                        'test'A

Thousand thanks. It's exactly what I'm looking for. I'll test it in a couple of hours and I'll return to you, to confirm you that it works like a charm.;-)
As I can imagine, is there an equivalent reverse function to transform string to unicode ?

Collectives™ on Stack Overflow

How to transform a string from a delphi code source into a standard string to be saved in a database?

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related