Batch file IF statement fails with "was unexpected at this time"

Question

I have a batch file that does the following:

@IF EXIST "C:\Program Files\MyAppFolder" (
  icacls "C:\Program Files\MyAppFolder" /inheritance:r
  icacls "C:\Program Files\MyAppFolder" /GRANT SYSTEM:(CI)(OI)(F)
  icacls "C:\Program Files\MyAppFolder" /GRANT Administrators:(CI)(OI)(F)
)

Individually the commands work fine but put together like this in an IF statement I get this error and the script stops in its tracks:

(OI)(F) was unexpected at this time.

If I just have a single command in the IF statement then it works fine.

I'm guessing that you're only permitted one statement between the IF parenthesis?

This happens on Windows 2008 and Windows 2003 (with the ICACLS hotfix).

sth · Accepted Answer · 2017-05-19 13:35:15Z

33

The shell seems to think that the ) in the third line of your command is the closing parenthesis for the one opened in the first line. You need to quote the arguments containing parenthesis:

@IF EXIST "C:\Program Files\MyAppFolder" (
  icacls "C:\Program Files\MyAppFolder" /inheritance:r
  icacls "C:\Program Files\MyAppFolder" /GRANT "SYSTEM:(CI)(OI)(F)"
  icacls "C:\Program Files\MyAppFolder" /GRANT "Administrators:(CI)(OI)(F)"
)

edited May 19, 2017 at 13:35

answered Jun 25, 2011 at 15:38

sth

231k56 gold badges288 silver badges370 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Kev Over a year ago

Bloody obvious and I should have known better :) Thanks.

a25bedc5-3d09-41b8-82fb-ea6c353d75ae Over a year ago

It is 2017 and people like me still need this.. it definitely was not obvious!!

fzzylogic Over a year ago

For usernames with spaces (for example "IIS AppPool\PoolName", use separate inverted commas for sid & perm: /GRANT "SYSTEM":"(CI)(OI)(F)"

Yobibyte · Accepted Answer · 2017-10-11 19:02:30Z

0

The above answer won't work if you need to assign permissions to a user with a space in their name (EG: "CREATOR OWNER")

A better solution is to use a function with call:

@ECHO OFF

IF EXIST "C:\Program Files\MyAppFolder" (
   CALL:Permissions
)

GOTO:eof

:Permissions
   icacls "C:\Program Files\MyAppFolder" /inheritance:r
   icacls "C:\Program Files\MyAppFolder" /GRANT SYSTEM:(CI)(OI)(F)
   icacls "C:\Program Files\MyAppFolder" /GRANT Administrators:(CI)(OI)(F)
   GOTO:eof

The GOTO:eof is required at the end of the function.

Detailed information on functions in batch can be found here.

answered Oct 11, 2017 at 19:02

Yobibyte

1

Collectives™ on Stack Overflow

Batch file IF statement fails with "was unexpected at this time"

2 Answers 2

3 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related