Conditional environment variables in Jenkins Declarative Pipeline

Question

I'm trying to get a declarative pipeline that looks like this:

pipeline {
    environment {
        ENV1 = 'default'
        ENV2 = 'default also'
    }
}

The catch is, I'd like to be able to override the values of ENV1 or ENV2 based on an arbitrary condition. My current need is just to base it off the branch but I could imagine more complicated conditions.

Is there any sane way to implement this? I've seen some examples online that do something like:

stages {
    stage('Set environment') {
        steps {
            script {
                ENV1 = 'new1'
            }
        }
    }
}

But I believe this isn't setting the actually environment variable, so much as it is setting a local variable which is overriding later calls to ENV1. The problem is, I need these environment variables read by a nodejs script, and those need to be real machine environment variables.

Is there any way to set environment variables to be dynamic in a jenkinsfile?

hc_dev · Accepted Answer · 2022-07-14 15:05:12Z

119

Maybe you can try Groovy's ternary-operator:

pipeline {
    agent any
    environment {
        ENV_NAME = "${env.BRANCH_NAME == "develop" ? "staging" : "production"}"
    }
}

or extract the conditional to a function:

 pipeline {
        agent any
        environment {
           ENV_NAME = getEnvName(env.BRANCH_NAME)
        }
    }

// ...

def getEnvName(branchName) {
    if("int".equals(branchName)) {
        return "int";
    } else if ("production".equals(branchName)) {
        return "prod";
    } else {
        return "dev";
    }
}

But, actually, you can do whatever you want using the Groovy syntax (features that are supported by Jenkins at least)

So the most flexible option would be to play with regex and branch names...So you can fully support Git Flow if that's the way you do it at VCS level.

edited Jul 14, 2022 at 15:05

hc_dev

9,6941 gold badge30 silver badges47 bronze badges

answered Dec 13, 2018 at 23:02

Drasko Vrucinic

1,2442 gold badges8 silver badges5 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Max Cascone Over a year ago

amazing, this works perfectly; my example is environment { branch = env.BRANCH_NAME ?: 'tester' } needs to be environment { "${branch = env.BRANCH_NAME ?: 'tester'}"

Sumith08 Over a year ago

How can we use this solution when we have 3 conditions?

Max Cascone Over a year ago

@Sumith08 - any logic should work within the closure in the example. It's a really neat trick to set env vars dynamically.

stricq Over a year ago

This doesn't work. First of all the quotes are wrong. After changing to single quotes inside the double quotes, Jenkins still blows up on this syntax.

Drasko Vrucinic Over a year ago

The answer is updated according to your concerns. Thx

|

burnettk · Accepted Answer · 2017-05-16 17:50:03Z

14

use withEnv to set environment variables dynamically for use in a certain part of your pipeline (when running your node script, for example). like this (replace the contents of an sh step with your node script):

pipeline {
    agent { label 'docker' }
    environment {
        ENV1 = 'default'
    }
    stages {
        stage('Set environment') {
            steps {
                sh "echo $ENV1" // prints default
                // override with hardcoded value
                withEnv(['ENV1=newvalue']) {
                    sh "echo $ENV1" // prints newvalue
                }
                // override with variable
                script {
                    def newEnv1 = 'new1'
                    withEnv(['ENV1=' + newEnv1]) {
                        sh "echo $ENV1" // prints new1
                    }
                }
            }
        }
    }
}

answered May 16, 2017 at 17:50

burnettk

14.1k5 gold badges55 silver badges56 bronze badges

1 Comment

Paul Sachs Over a year ago

Ah yes, this does work. It's unfortunate that there is no way to do it for all stages, but this will have to do for now. Thanks!

stricq · Accepted Answer · 2020-05-11 21:50:11Z

11

Here is the correct syntax to conditionally set a variable in the environment section.

environment {
    MASTER_DEPLOY_ENV = "TEST" // Likely set as a pipeline parameter
    RELEASE_DEPLOY_ENV = "PROD" // Likely set as a pipeline parameter
    DEPLOY_ENV = "${env.BRANCH_NAME == 'master' ? env.MASTER_DEPLOY_ENV : env.RELEASE_DEPLOY_ENV}"
    CONFIG_ENV = "${env.BRANCH_NAME == 'master' ? 'MASTER' : 'RELEASE'}"
}

answered May 11, 2020 at 21:50

stricq

87410 silver badges20 bronze badges

3 Comments

Abid Khan Over a year ago

Can we do it in parameters{} section? I tried to do it but it does not like it at all.

stricq Over a year ago

@AbidKhan I have not used the parameters section, so I couldn't say.

hc_dev Over a year ago

The ternary-operator as assignment solution was already answered by Drasko years ago. What is the difference here if any?

Karrde · Accepted Answer · 2018-09-24 00:55:49Z

2

I managed to get this working by explicitly calling shell in the environment section, like so:

UPDATE_SITE_REMOTE_SUFFIX = sh(returnStdout: true, script: "if [ \"$GIT_BRANCH\" == \"develop\" ]; then echo \"\"; else echo \"-$GIT_BRANCH\"; fi").trim()

however I know that my Jenkins is on nix, so it's probably not that portable

answered Sep 24, 2018 at 0:55

Karrde

4812 silver badges9 bronze badges

Comments

assafp · Accepted Answer · 2022-05-15 06:07:16Z

2

Here is a way to set the environment variables with high flexibility, using maps:

    stage("Environment_0") {
        steps {
            script {
                def MY_MAP = [ME: "ASSAFP", YOU: "YOUR_NAME", HE: "HIS_NAME"]
                env.var3 = "HE"
                env.my_env1 = env.null_var ? "not taken" : MY_MAP."${env.var3}"
                echo("env.my_env1: ${env.my_env1}")                 
           }
        }
    }

This way gives a wide variety of options, and if it is not enough, map-of-maps can be used to enlarge the span even more. Of course, the switching can be done by using input parameters, so the environment variables will be set according to the input parameters value.

answered May 15, 2022 at 6:07

assafp

776 bronze badges

Comments

Jinsoo Heo · Accepted Answer · 2018-01-12 05:03:00Z

-1

pipeline {
    agent none
    environment {
        ENV1 = 'default'
        ENV2 = 'default'
    }
    stages {
        stage('Preparation') {
            steps {
                script {
                    ENV1 = 'foo' // or variable
                    ENV2 = 'bar' // or variable
                }
                echo ENV1
                echo ENV2
            }
        }
        stage('Build') {
            steps {
                sh "echo ${ENV1} and ${ENV2}"
            }
        }
        // more stages...
    }
}

This method is more simple and looks better. Overridden environment variables will be applied to all other stages also.

answered Jan 12, 2018 at 5:03

Jinsoo Heo

3262 silver badges12 bronze badges

2 Comments

Kutzi Over a year ago

Actually this doesn't overwrite the environment variable, but defines a new global-scope Groovy variable (I think) Try to echo ${env.ENV1} int the Build stage and you'll see that it still has the original value!

user6017989 Over a year ago

environment{} can be used at the stage level for that. However it seems that it needs to be repeated for every stage where it is needed.

Hmbucker · Accepted Answer · 2018-06-01 13:02:46Z

-1

I tried to do it in a different way, but unfortunately it does not entirely work:

pipeline {
  agent any
  environment {
    TARGET = "${changeRequest() ? CHANGE_TARGET:BRANCH_NAME}"
  }

  stages {
    stage('setup') {
        steps {
            echo "target=${TARGET}"
            echo "${BRANCH_NAME}"
        }
    }
  }
}

Strangely enough this works for my pull request builds (changeRequest() returning true and TARGET becoming my target branch name) but it does not work for my CI builds (in which case the branch name is e.g. release/201808 but the resulting TARGET evaluating to null)

edited Jun 1, 2018 at 13:02

answered May 31, 2018 at 16:51

Hmbucker

1253 silver badges11 bronze badges

Collectives™ on Stack Overflow

Conditional environment variables in Jenkins Declarative Pipeline

7 Answers 7

7 Comments

1 Comment

3 Comments

Comments

Comments

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

7 Answers 7

7 Comments

1 Comment

3 Comments

Comments

Comments

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related