How to sending JavaScript results from local file to VBA Webbrowser control

Question

I'm using the standard webbrowser control in MS Access. The control shows a local HTML file. Now, I want to send data from HTML to VBA.

<input type="text" onchange="foo(this.value)">

How to send data to VBA? I have two problems:

If the HTML file is local, I found no solution to start JavaScript at all. If the file has an http URI, alert() for example is possible, but not if the file is local. How can I use JavaScript in a local file?
How can I send the result of a JavaScript function to VBA?

PS.: I'm not searching how to start Javascript from VBA (Webbrowser.Document.parentwindow.execscript)

Thx

Martin

stackoverflow.com/questions/7388391/…

Tim Williams
– Tim Williams

2017-05-15 20:27:11 +00:00
Commented May 15, 2017 at 20:27 — Tim Williams
– Tim Williams, Commented May 15, 2017 at 20:27

Tim Williams · Accepted Answer · 2017-05-17 03:14:29Z

4

You can set up js-to-VBA communication using simple classes implementing WithEvents to hook up VBA references to elements in your hosted HTML page.

When the example below is run, editing and then clicking out of the HTML textbox (so firing the onchange event) will trigger a VBA messagebox via the class field linked to the input.

To find out how to fix your issues with local pages and js, Google "mark of the web".

In class module clsHtmlText:

Option Explicit

Private WithEvents txt As MSHTML.HTMLInputElement

Public Sub SetText(el)
    Set txt = el
End Sub

Private Function txt_onchange() As Boolean
    MsgBox "changed: " & txt.value
End Function

In a UserForm with an embedded browser control wb1:

Option Explicit

Dim o As clsHtmlText '<< instance of our "withEvents" class

Private Sub UserForm_Activate()

    Dim el As MSHTML.HTMLInputElement
    With Me.wb1
        .Navigate "about:blank"
        WaitFor wb1
        .Document.Open "text/html"
        'or you can load a page from a URL/file
        'Note: local pages need "mark of the web" in the markup
        .Document.write "<html><input type='text' size=10 id='txtHere'></html>"
        .Document.Close
        WaitFor wb1

        Set el = .Document.getelementbyId("txtHere")

        Set o = New clsHtmlText
        o.SetText el '<< assign the textbox so we can monitor for change events

    End With

End Sub

'utility sub to ensure page is loaded and ready
Sub WaitFor(IE)
    Do While IE.ReadyState < 4 Or IE.Busy
        DoEvents
    Loop
End Sub

edited May 17, 2017 at 3:14

answered May 15, 2017 at 20:35

Tim Williams

169k8 gold badges104 silver badges143 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

6diegodiego9 Over a year ago

Thanks for this solution! I just add that a separate class such as clsHtmlText is not technically needed, we can have it all inside the userform module, which also supports the declaration with WithEvents.

Collectives™ on Stack Overflow

How to sending JavaScript results from local file to VBA Webbrowser control

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related