Nested loop in RobotFramework

Question

I need to create a nested loop in Robot framework. Can you please Help me do it?

${contents}=    Get File    ${file path}
 @{lines}=    Split to lines    ${contents}
 ${matched elements}=    Get Webelements    ${LABEL PORTAIL XPATH }
 : FOR    ${element}    IN    @{matched elements}
 \    ${text}=    Get Text    ${element}
 \    : FOR    ${line}    IN    @{lines}
 \    Run Keyword If    '${text}' == '${line}'    Log    '${text} matched'

I need to have a nested loop which compares all the ${text} with all the @{lines} in the file.

Thanks in Advance

Todor Minakov · Accepted Answer · 2021-04-28 18:47:23Z

5

No nested loops in RF; that can be done only by calling a keyword with the inner loop, in the outer one.

In your particular case though, you could go without it - as you want to match the full line, that's doable through Should Contain:

${contents}=    Get File    ${file path}
@{lines}=    Split to lines    ${contents}
${matched elements}=    Get Webelements    ${LABEL PORTAIL XPATH }
: FOR    ${element}    IN    @{matched elements}
\  ${text}=     Get Text    ${element}
\  ${present}=  Run Keyword And Return Status    Should Contain    ${lines} 
${text}
\    Run Keyword If  ${present}    Log    '${text} matched'

If you were going after a partial match - i.e. ${text} to be a part of a ${lines} member, then it wouldn't be possible like this.

edited Apr 28, 2021 at 18:47

answered Apr 21, 2017 at 17:14

Todor Minakov

20.2k3 gold badges61 silver badges63 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Todor Minakov · Accepted Answer · 2021-02-26 15:44:12Z

3

Starting with the 4.0 release, Robot Framework (finally :) has support for nested for loops.
So the code in the question, with the new FOR syntax will be:

${contents}=  Get File    ${file path}
@{lines}=     Split to lines    ${contents}
${matched elements}=    Get Webelements    ${LABEL PORTAIL XPATH }
FOR    ${element}    IN    @{matched elements}
    ${text}=    Get Text    ${element}
    FOR    ${line}    IN    @{lines}
        Run Keyword If    '${text}' == '${line}'    Log    '${text} matched'
    END
END

The 4.0 version brings also IF/ELSE flow control, so the inner loop can be made to break on the 1st match with it:

    FOR    ${line}    IN    @{lines}
        IF    '${text}' == '${line}'
            Log    '${text} matched'
            Exit For Loop
        END
    END

, vs "the old way" of doing that with Run Keyword If and `Run Keywords:

    FOR    ${line}    IN    @{lines}
        Run Keyword If    '${text}' == '${line}'    Run Keywords    Log    '${text} matched'
                                                       ...    AND   Exit For Loop
    END

answered Feb 26, 2021 at 15:44

Todor Minakov

20.2k3 gold badges61 silver badges63 bronze badges

1 Comment

Bence Kaulics Over a year ago

I wonder whether Tidy will reformat Run Keyword If calls to the new IF syntax. It would be nice.

Jan Kovařík · Accepted Answer · 2017-04-21 14:16:06Z

2

It isn't possible without custom keyword containing the inner loop. See doc: http://robotframework.org/robotframework/latest/RobotFrameworkUserGuide.html#nested-for-loops

I'd say that such logic should be always written using some stronger language (python, java...) and then just called from RF.

answered Apr 21, 2017 at 14:16

Jan Kovařík

1,5821 gold badge11 silver badges18 bronze badges

Comments

Maheswara Reddy K · Accepted Answer · 2021-08-20 05:55:51Z

1

*** Settings ***

Documentation Learning Robot Framework

*** Variables ***

*** Keywords ***

Keyword with for loop

[Arguments]     ${x}

FOR     ${y}    IN RANGE    1   5

    Log To Console      ${x} ${y}

END

*** Test Cases ***

Nested for loop example

FOR   ${x}   IN RANGE   1   5

    Keyword with for loop       ${x}

END

edited Aug 20, 2021 at 5:55

answered Aug 20, 2021 at 5:49

Maheswara Reddy K

112 bronze badges

Comments

Mayur Agarwal · Accepted Answer · 2017-10-05 10:46:29Z

0

Nested for loops

Having nested for loops is not supported directly, but it is possible to use a user keyword inside a for loop and have another for loop there.

*** Keywords ***
Handle Table
    [Arguments]    @{table}
    :FOR    ${row}    IN    @{table}
    \    Handle Row    @{row}

Handle Row
    [Arguments]    @{row}
    :FOR    ${cell}    IN    @{row}
    \    Handle Cell    ${cell}

Referenced from : http://robotframework.org/robotframework/latest/RobotFrameworkUserGuide.html#nested-for-loops

answered Oct 5, 2017 at 10:46

Mayur Agarwal

85410 silver badges28 bronze badges

Collectives™ on Stack Overflow

Nested loop in RobotFramework

5 Answers 5

Comments

1 Comment

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

1 Comment

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related