How to check if variable in array in vbscript

Question

I'm refactoring my code and trying to cut down on repetition. I've got this working code

<% If tree <> "" or (info <> "" and info <> "links" and info <> "privacy" and info <> "talks") Then %>
            write stuff
<% End If %>

I put the info variables into an array

Dim info(3)
info(0) = "Talks"
info(1) = "Privacy"
info(2) = "Links"

I'm unclear as to iterate through the array

<% If tree <> "" or (info <> "" and **info <> arrayInfo** Then %>
            write stuff
<% End If %>

Little help. Thanks.

Ekkehard.Horner · Accepted Answer · 2017-02-13 16:10:12Z

8

You need a dictionary if you want to use one expression (.Exists) to obtain a fact (contained or not) about all elements of a collection. Look at:

Option Explicit

Dim aInfo(2)  ' last index; not size
aInfo(0) = "Talks"
aInfo(1) = "Privacy"
aInfo(2) = "Links"
Dim dicInfo : Set dicInfo = CreateObject("Scripting.Dictionary")
dicInfo.CompareMode = vbTextCompare
Dim i
For Each i In aInfo
    dicInfo(i) = 0
Next
For Each i In Split("Talks Other Links Else")
    If dicInfo.Exists(i) Then
       WScript.Echo i, "found"
    Else
       WScript.Echo "no", i, "in", Join(dicInfo.Keys())
    End If
Next

output:

cscript 42207316.vbs
Talks found
no Other in Talks Privacy Links
Links found
no Else in Talks Privacy Links

answered Feb 13, 2017 at 16:10

Ekkehard.Horner

38.8k2 gold badges50 silver badges101 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Vanquished Wombat · Accepted Answer · 2017-02-13 17:12:40Z

Another technique is to create a string and instr().

InStr([start,]string1,string2[,compare]) If string2 is not found in string1 then InStr returns 0.

Note that the pipe separator is important at both the first and final positions of the string we search AND what we are seeking to match. Otherwise you get false-positives.

<%
dim sText 
sText="|Talks|Privacy|Links|"

  If tree <> "" or (len(info) > 0 and instr(1, sText, "|" info & "|") ) Then %>
            write stuff
<% End If %>

The technique is worthwhile with a few strings to test. The default compare mode is case sensitive but you can make it insensitive.

See http://www.w3schools.com/asp/func_instr.asp for details.

It is less purist than using a dictionary but worth being aware of.

StackHound25 · Accepted Answer · 2017-02-14 16:30:09Z

2

Although I agree with the above answer using the Instr function, there is an alternative. Your question is asking how to iterate through the array to test the values. Use a For..Next loop. Code example below.

dim arrInfo(2)
dim blnInfoGood

blnInfoGood = true

arrInfo(0) = "Talks"
arrInfo(1) = "Privacy"
arrInfo(2) = "Links"

for k = lbound(arrInfo) to ubound(arrInfo)
    if info = arrInfo(k) then
        blnInfoGood = false
        exit for
    end if
next

if tree <> "" or blnInfoGood then
    ' Write stuff
end if

Hope this helps.

answered Feb 14, 2017 at 16:30

StackHound25

213 bronze badges

Comments

Robert S · Accepted Answer · 2017-02-16 20:26:16Z

2

Use a dictionary AND use a simpler conditional.

<%
set obj = server.createObject("scripting.dictionary")

obj.add "links", "links"
obj.add "privacy", "privacy"
obj.add "talks", "talks"

if tree <> "" and obj.exists(info)=false then
     'write stuff
end if

set obj = nothing
%>

answered Feb 16, 2017 at 20:26

Robert S

4966 silver badges17 bronze badges

Comments

Daniel · Accepted Answer · 2017-02-27 14:15:31Z

-1

Here's the simplest way to iterate through the array since you asked specifically about that.

    Dim info(3)
    info(0) = "Talks"
    info(1) = "Privacy"
    info(2) = "Links"

    for i = 0 to 2
        if tree = info(i) then
            'do stuff here with match
        end if
    next

answered Feb 27, 2017 at 14:15

Daniel

1432 silver badges13 bronze badges

4 Comments

Ekkehard.Horner Over a year ago

Bad version of @StackHound25's answer (wrong ubound, no exit)

Daniel Over a year ago

@Ekkehard.Horner Simpler version of Stackhound's answer and not the wrong ubound. The array will touch subscripts 0, 1, and 2. While the UBound value might actually be 3 here, that's not how the loop would be written. I intentionally do not use UBound when the array size is known and fixed, personal preference I guess. And exit falls under "do stuff here". I thought that would be obvious. Why are so many people so quick to downvote on here?

Ekkehard.Horner Over a year ago

Because many people post low-quality code and find lame excuses for their blunders ('personal preference', how can 'exit' possibly fall under 'do stuff here with match'?)

Daniel Over a year ago

@Ekkehard.Horner Gimme a break, it's obvious you're just downvoting because you have an answer here. Exit most definitely falls under "do stuff here" because "Do stuff here" means do what you need to do with the matching value and exit is not necessarily what he may need to do here. Exit is not the only option so therefore I included it. Regardless, the answer works and is SIMPLE. That's what I was trying to provide the OP since no one else has.

Maxwell Robert · Accepted Answer · 2025-09-24 15:16:56Z

-1

Heres a clean way:

Dim isIn
Dim opt
Dim ok

ok = false
isIn = "100"

opt=Split("0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19")

for i = Lbound(opt) to Ubound(opt)
    if opt(i) = isIn then
        ok = true
    end if
next

MsgBox "Value found " & ok
Wscript.Quit

edited Sep 24 at 15:16

answered Sep 24 at 15:16

Maxwell Robert

11 bronze badge

1 Comment

Community Sep 24 at 15:59

As it’s currently written, your answer is unclear. Please edit to add additional details that will help others understand how this addresses the question asked. You can find more information on how to write good answers in the help center.

Collectives™ on Stack Overflow

How to check if variable in array in vbscript

6 Answers 6

Comments

Comments

Comments

Comments

4 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

Comments

Comments

Comments

Comments

4 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related