vbscript for each loop to for loop

Question

Hi I have written a program in VBScript, now I want to replace For Each loop with a For loop.

For Each node In objMSXML.selectNodes(sXPath)                   
    Set li = document.createElement("li")
    li.innerText = i & " " & node.text
    ul.appendChild li
    i = i +1
Next

I have not been able to figure it out as I also need to know the number of nodes returned from Xpath.

Why do you want to use a For instead of a For Each? If it's because you want to workout the number of nodes you don't need to the IXMLDOMNodeList is a collection so just use the length property like this NumOfNodes = objMSXML.selectNodes(sXPath).length to retrieve the number of nodes. — user692942
– user692942, Commented Mar 17, 2016 at 7:22
This is a duplicate anyway - XPath count in VBScript - See How to Ask — user692942
– user692942, Commented Mar 17, 2016 at 9:29

Community · Accepted Answer · 2017-05-23 12:07:53Z

3

Following on from my initial comment.

The selectNodes() method returns a IXMLDOMNodeList object which is a NodeList collection.

As with any collection it contains members common to collection objects

Properties

length - Number of Nodes in the collection

Methods

item - Access to individual Nodes within the collection

_{For full list of member properties and methods see
IXMLDOMNodeList
Members}

There should be no logical reason why you need to change your For Each to a For loop as you can just use the length property to retrieve the number of Nodes in the collection.

Option Explicit

Dim node, nodes, li, i, sXPath, NumberOfNodes
Set nodes = objMSXML.selectNodes(sXPath)
'Retrieve number of Nodes
NumberOfNodes = nodes.length
For Each node In nodes                   
    Set li = document.createElement("li")
    li.innerText = i & " " & node.text
    ul.appendChild li
    i = i +1
Next

Useful Links

edited May 23, 2017 at 12:07

CommunityBot

11 silver badge

answered Mar 17, 2016 at 10:02

user692942

16.4k8 gold badges85 silver badges196 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

user692942 Over a year ago

What was the reason for un-accepting? Does the solution not work is there a problem with the code?

user692942 · Accepted Answer · 2016-03-17 10:56:24Z

2

The node list returned by .SelectNodes() is a collection with a .length property that can be traversed using a zero-based integer index:

Option Explicit

Dim oFS    : Set oFS  = CreateObject("Scripting.FileSystemObject")
Dim sFSpec : sFSpec   = oFS.GetAbsolutePathName("..\data\33921005.xml")
Dim oXML   : Set oXML = CreateObject("Msxml2.DOMDocument.6.0")
oXML.load sFSpec
If 0 = oXML.parseError Then
   Dim ndlName : Set ndlName = oXML.selectNodes("/Envelope/Body/Request/individual/hasName/*")
   Dim ndName
   For Each ndName In ndlName
       WScript.Echo ndName.tagName
   Next
   Dim iNd
   For iNd = 0 To ndlName.length - 1
       WScript.Echo iNd, ndlName(iNd).tagName
   Next
Else
   WScript.Echo oXML.parseError.reason
End If

output:

cscript 36053711.vbs
firstName
lastName
0 firstName
1 lastName

edited Mar 17, 2016 at 10:56

user692942

16.4k8 gold badges85 silver badges196 bronze badges

answered Mar 17, 2016 at 7:31

Ekkehard.Horner

38.8k2 gold badges50 silver badges101 bronze badges

2 Comments

user692942 Over a year ago

We know.

user692942 Over a year ago

What's with If 0 = oXML.parseError Then maybe it's just me but doing like that is triggering my OCD, is there some benefit to that?

Collectives™ on Stack Overflow

vbscript for each loop to for loop

2 Answers 2

Useful Links

1 Comment

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Useful Links

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related