Batch script to search multiple string in multiple files

Question

I tried to write a batch script to do the below task

I have list of 1000 unique Employee IDs (numerical IDs, no. of digits may differ) in a text file called empids.txt. And also I have folder called MasterIDs which contains multiple text files and each text file has 100 thousand IDs

I tried a batch script to search the 1000 IDs listed in the empids.txt and show the whether any listed ids are present in the multiple textfiles in the MasterIDs folder. The expected result is like the below

expected output

12345678 is found in *.txt
1145897 is not found

below is the batch script i tried and I am not getting the expected output. It just searches and give the whole line which contains the searched string.

set manifest_folder=\\vfiler-padhu\padhu\*.txt
set file_list=\\vfiler-padhu\padh\File_list.txt
set tmpFile=\\vfiler-padhu\padh\tmpFile.txt
for /f "delims=" %%f in (%file_list%) do (
findstr /L  %%f %manifest_folder% >> %tmpFile%
) 
pause

I am just started learning batch script. Kindly help to do this task.

Do you need the name of the file where the id is found or only to know it has been found? — MC ND
– MC ND, Commented Aug 20, 2014 at 10:49

MC ND · Accepted Answer · 2014-08-20 14:18:59Z

1

@echo off
setlocal enableextensions disabledelayedexpansion

set "manifest_folder=\\vfiler-padhu\padhu\*.txt"
set "file_list=\\vfiler-padhu\padh\File_list.txt"
set "tmpFile=\\vfiler-padhu\padh\tmpFile.txt"

    (for /f "usebackq delims=" %%a in ("%file_list%") do (
        set "found="
        for /f "delims=" %%b in ('findstr /l /m /c:"%%a" "%manifest_folder%"') do (
            echo %%a is found in %%~nxb
            set "found=1"
        )
        if not defined found (
            echo %%a is not found
        )
    )) > "%outputFile%"

This will read input file and for each line/id a search in the manifest folder is executed, asking for the name of the files where the id is found.

edited Aug 20, 2014 at 14:18

answered Aug 20, 2014 at 11:00

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

sparker Over a year ago

Works great. Thank you. Marked as answer.

Collectives™ on Stack Overflow

Batch script to search multiple string in multiple files

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related