Setting Variables in Variables in Batch

Question

I'm trying to efficiently name variables a1 through a9 with !%f%! through !%q%!. I tried creating a for loop to complete this:

set w=0
for %%K in (f g h i k l m o q) do (
    set /a w+=1
    set /a b%w%=%!%%K!%
    set /a a%w%=!b%w%!%%13
)

The error is that there is a missing operator, so I'm assuming that the parenthesis and exclamation marks are being misread. How would I go about fixing this problem?

TL;DR

Make:

set /a a1=!%f%!%%13
...
set /a a9=!%q%!%%13

...more efficient.

To clarify, %f% is equal to say 4D and %4D% is equal to 9.

I need the modulus of 9 and 13 as the a1.

Won't fix it, but instead of doing set /a w=w+1 - you should do set /a w+=1. — unclemeat
– unclemeat, Commented Jan 19, 2014 at 22:47
Pretty much. What is the point of setting your b1 through b9 variables? — unclemeat
– unclemeat, Commented Jan 19, 2014 at 22:52
I was just trying to eliminate a pair of percent signs in an attempt to fix the problem, and does set /a w-=1 decrement w? — user3093536
– user3093536, Commented Jan 19, 2014 at 22:54
Also, setting w to 0 is not necessary at the start. setting an empty variable using /a and +=1 will set the variable to 1. — unclemeat
– unclemeat, Commented Jan 19, 2014 at 22:56

dbenham · Accepted Answer · 2014-01-20 01:19:53Z

2

I believe at least one problem you are facing, based on your comment below your question, is that a variable name of 4D will be interpreted by SET /A as the number 4 followed by variable D, which would be invalid.

Another issue you have is that the expansion of %w% will be a constant value within the loop. You need delayed expansion !w! instead.

I believe this is what you want.

set w=0
for %%K in (f g h i k l m o q) do (
  set /a w+=1
  for %%V in (!%%K!) do set /a a!w!=!%%V!%%13
)

If none of your variable names begin with a number, then you could simply use

set w=0
for %%K in (f g h i k l m o q) do (
  set /a w+=1
  set /a a!w!=!%%K!%%13
)

I try to avoid using a number as the leading character for a variable name for two reasons:

1) SET /A will not expand the variable properly, as you are experiencing in your question.

2) Normal expansion of %4D% would be interpreted as value of argument %4, followed by D, followed by a % that would be stripped from the result.

edited Jan 20, 2014 at 1:19

answered Jan 20, 2014 at 0:00

dbenham

132k29 gold badges272 silver badges410 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

user3093536 Over a year ago

So is this generally how I can fix my problem with variables starting with numbers in any case? Because right now I am naming the variables a2D, a4C, etc. and then making them substrings.

user3093536 Over a year ago

And I'm slightly unclear on the usage of !%%K! instead of just %%K in the for %%V loop

dbenham Over a year ago

See my updated answer as to why a variable name starting with a number is to be avoided. The value of %%K is f. I use !%%K! to get the string 4D into %%V so that I can then use !%%V! which equates to !4D!.

unclemeat · Accepted Answer · 2014-01-19 23:10:51Z

0

setLocal enableDelayedExpansion
set w=0
for %%K in (f g h i k l m o q) do (
    set /a w+=1
    set a!w!=^^!%%%%K%%^^!%%%%13
)

:: as a test
echo !a5!

This should do the trick for you. Carat ^ is the batch escape character.

edited Jan 19, 2014 at 23:10

answered Jan 19, 2014 at 22:59

unclemeat

5,2075 gold badges32 silver badges55 bronze badges

5 Comments

dbenham Over a year ago

That cannot possibly work - the expansion of %w% will remain constant within the loop. Delayed expansion is needed. Also, I don't know what you are attempting with the carets - you cannot escape a % with a caret.

unclemeat Over a year ago

Yeah, realized my various obvious problems after testing it.

user3093536 Over a year ago

The output that I am getting is: !%f%!%%13

user3093536 Over a year ago

I need the actual result of the operation

unclemeat Over a year ago

So if %f% expands to foo and !foo! expands to bar you're expecting the output to be bar%%13?

Collectives™ on Stack Overflow

Setting Variables in Variables in Batch

2 Answers 2

3 Comments

5 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

5 Comments

Your Answer

Sign up or log in

Post as a guest

Related