Check if service is running without using Find command

Question

In a batch file I'm trying to check if a service is started, if not then wait.

Now to check if a service is running, I am doing this:

sc query "serviceName" | find /i "RUNNING"
if "%ERRORLEVEL%"=="0" (
    echo serviceName is running.
) else (
    echo serviceName is not running
)

Trouble is the errorlevel is always set to 0. Possibly because of this known Find bug. Is there any alternate way to check if a service is started, if not then wait?

Avoid to "reset" the %errorlevel% variable in your code. If you set it to any value, commands will set correctly the errorlevel value BUT NOT the %errorlevel% variable. — MC ND
– MC ND, Commented Oct 21, 2013 at 11:53

ElektroStudios · Accepted Answer · 2013-10-21 10:52:03Z

10

You could use Findstr instead of Find command:

sc query "Service name" | findstr /i "RUNNING" 1>nul 2>&1 && (
    echo serviceName is running.
) || (
    echo serviceName is not running
)

You can do it also using wmic command:

wmic service where name="Service name" get State | Findstr /I "Running" 1>NUL 2>&1 && (
    echo serviceName is running.
) || (
    echo serviceName is not running
)

Another thing to notice for the future is that when comparing numeric values you should not enclose expressions with quotes "", so the condition should look like this:

If %ERRORLEVEL% EQU 0 () ELSE ()

edited Oct 21, 2013 at 10:52

answered Oct 21, 2013 at 10:43

ElektroStudios

20k39 gold badges222 silver badges462 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

foxidrive · Accepted Answer · 2013-10-21 11:19:14Z

8

Your code will work fine, if you aren't using Windows NT version 3.1 and Windows NT Advanced Server version 3.1 and your service name doesn't include running.

Perhaps it is within a loop and so you should use this (or delayed expansion):

sc query "serviceName" | find /i "RUNNING"
if not ERRORLEVEL 1 (
    echo serviceName is running.
) else (
    echo serviceName is not running
)

answered Oct 21, 2013 at 11:19

foxidrive

41.4k11 gold badges61 silver badges71 bronze badges

1 Comment

npocmaka Over a year ago

aah.Brackets block.Didn't come to me.+1

npocmaka · Accepted Answer · 2013-10-21 11:59:01Z

4

Works for me.Is it possible your ERRORLEVEL variable to be overwriten or your code to be in brackets block? try one of these:

sc query "serviceName" | findstr /i "RUNNING"
if not errorlevel 1 (
    echo serviceName is running.
) else (
    echo serviceName is not running
)

or

sc query "serviceName" | findstr /i "RUNNING" && (
    echo serviceName is running.
    goto :skip_not_w
) 
echo serviceName is not running
:skip_not_w

The cited bug is for windows nt (is this your OS?) and should be fixed already...If your os is NT , you should parse the output of the command with FOR /F to see it contains RUNNING or use FINDSTR

edited Oct 21, 2013 at 11:59

answered Oct 21, 2013 at 10:48

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Comments

Samuel Nicholson · Accepted Answer · 2013-10-21 10:42:13Z

3

for /F "tokens=3 delims=: " %%H in ('sc query "serviceName" ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (
   echo Service not started
   net start "serviceName"
  )
)

answered Oct 21, 2013 at 10:42

Samuel Nicholson

3,6293 gold badges23 silver badges37 bronze badges

Comments

Matt Williamson · Accepted Answer · 2013-10-21 11:49:43Z

1

Another way with a function:

:IsServiceRunning servicename
sc query "%~1"|findstr "STATE.*:.*4.*RUNNING">NUL

Usage Example:

Call :IsServiceRunning service && Service is running || Service isn't running

answered Oct 21, 2013 at 11:49

Matt Williamson

7,1691 gold badge27 silver badges39 bronze badges

Collectives™ on Stack Overflow

Check if service is running without using Find command

5 Answers 5

Comments

1 Comment

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

Comments

1 Comment

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related