Adding multiple namespace in XML using XSLT 1.0

Question

<application xmlns="http://someurl">
    <Detail1/>
    <Detail2>
    <Property/>
    </Detail2>
</application>

I am trying to add xmlns:xs="http://www.w3.org/2001/XMLSchema" and xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" to the "application root node". I tried to follow a lot of links on stackoverflow but nothing seemed to work in XSLT 1.0 Can someone help me with this.

G. Ken Holman · Accepted Answer · 2013-09-30 21:30:33Z

3

Since XSLT 1.0 doesn't have the <xsl:namespace> instruction in XSLT 2.0, the technique I use is to copy such nodes from my stylesheet:

Input:

t:\ftemp>type ns.xml
  <application xmlns="http://someurl">
    <Detail1/>
    <Detail2>
    <Property/>
    </Detail2>
</application>

Execution:

t:\ftemp>call xslt ns.xml ns.xsl
<?xml version="1.0" encoding="utf-8"?><application xmlns="http://someurl" xmlns:
xs="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchem
a-instance">
    <Detail1/>
    <Detail2>
    <Property/>
    </Detail2>
</application>

Stylesheet:

t:\ftemp>type ns.xsl
<?xml version="1.0" encoding="US-ASCII"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
                version="1.0">

<xsl:template match="/*">
  <xsl:copy>
    <xsl:copy-of select="document('')/*/namespace::xs"/>
    <xsl:copy-of select="document('')/*/namespace::xsi"/>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

<xsl:template match="@*|node()"><!--identity for all other nodes-->
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>
t:\ftemp>

answered Sep 30, 2013 at 21:30

G. Ken Holman

4,41318 silver badges15 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Vyomkesh Tiwari Over a year ago

Thanks for the quick reply. As i am new to xslt can you help me what does the below lines means: <xsl:copy-of select="document('')/*/namespace::xs"/> <xsl:copy-of select="document('')/*/namespace::xsi"/> I tried to run the code in the below tool, but showing me the original xml only. online-toolz.com/tools/xslt-transformation.php

G. Ken Holman Over a year ago

I indicated in my answer that I am copying the namespace nodes from the stylesheet using those instructions. My transcript shows the stylesheet is working with a conforming XSLT processor. If the stylesheet does not work for you, then you have a problem somewhere in your environment. I cannot tell you what is wrong with your environment.

Collectives™ on Stack Overflow

Adding multiple namespace in XML using XSLT 1.0

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related