Perl regex replacement string special variable

Question

I'm aware of the match, prematch, and postmatch predefined variables. I'm wondering if there is something similar for the evaluated replacement part of the s/// operator.

This would be particularly useful in dynamic expressions so they don't have to be evaluated a 2nd time.

For example, I currently have %regexs which is a hash of various search and replace strings.

Here's a snippet:

while (<>) {
  foreach my $key (keys %regexs) {   
    while (s/$regexs{$key}{'search'}/$regexs{$key}{'replace'}/ee) { 
      # Here I want to do something with just the replaced part 
      # without reevaluating.
    } 
  }
  print;
}

Is there a convenient way to do it? Perl seems to have so many convenient shortcuts, and it seems like a waste to have to evaluate twice (which appears to be the alternative).

EDIT: I just wanted to give an example: $regexs{$key}{'replace'} might be the string '"$2$1"' thus swapping the positions of some text in the string $regexs{$key}{'search'} which might be '(foo)(bar)' - thus resulting in "barfoo". The second evaluation that I'm trying to avoid is the output of $regexs{$key}{'replace'}.

FMc · Accepted Answer · 2009-11-25 12:23:50Z

2

Instead of using string eval (which I assume is what's going on with s///ee), you could define code references to do the work. Those code references can then return the value of the replacement text. For example:

use strict;
use warnings;

my %regex = (
    digits  => sub {
        my $r;
        return unless $_[0] =~ s/(\d)(\d)_/$r = $2.$1/e;
        return $r;
    },
);

while (<DATA>){
    for my $k (keys %regex){
        while ( my $replacement_text = $regex{$k}->($_) ){
            print $replacement_text, "\n";
        }
    }
    print;
}

__END__
12_ab_78_gh_
34_cd_78_yz_

edited Nov 25, 2009 at 12:23

answered Nov 21, 2009 at 23:43

FMc

42.5k13 gold badges81 silver badges135 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

hobbs · Accepted Answer · 2009-11-22 00:26:31Z

1

I'm pretty sure there isn't any direct way to do what you're asking, but that doesn't mean it's impossible. How about this?

{
  my $capture;
  sub capture {
    $capture = $_[0] if @_;
    $capture;
  }
}

while (s<$regexes{$key}{search}>
        <"capture('" . $regexes{$key}{replace}) . "')">eeg) {
  my $replacement = capture();
  #...
}

Well, except to do it really properly you'd have to shoehorn a little more code in there to make the value in the hash safe inside a singlequotish string (backslash singlequotes and backslashes).

answered Nov 22, 2009 at 0:26

hobbs

245k20 gold badges225 silver badges304 bronze badges

Comments

Schwern · Accepted Answer · 2009-11-23 23:41:26Z

1

If you do the second eval manually you can store the result yourself.

my $store;
s{$search}{ $store = eval $replace }e;

edited Nov 23, 2009 at 23:41

answered Nov 23, 2009 at 1:46

Schwern

167k28 gold badges225 silver badges370 bronze badges

2 Comments

cjm Over a year ago

The last $store is redundant, though; assignment returns the value assigned.

Schwern Over a year ago

Ahh, true. Also its redundant.

ennuikiller · Accepted Answer · 2009-11-21 22:45:58Z

0

why not assign to local vars before:

my $replace = $regexs{$key}{'replace'};

now your evaluating once.

answered Nov 21, 2009 at 22:45

ennuikiller

47.1k15 gold badges115 silver badges137 bronze badges

1 Comment

Keith Bentrup Over a year ago

Thx, but my question may have been unclear. I'm using the /ee modifier to evaluate what $regexs{$key}{'replace'} evaluates to, which may be dependent on $regexs{$key}{'search'}.

Collectives™ on Stack Overflow

Perl regex replacement string special variable

4 Answers 4

Comments

Comments

2 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

Comments

Comments

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related