Showing xml elements in an HTML table using xslt

Question

I am new in XSLT.I have an XML file and I want to use xslt to show the information in the xml file into a table. but I can the information in a row like this:

apfel 8.97 Fa. Krause Kirschen 10.45 Fa. Helbig apfel 12.67 Fa. Liebig this is my XML file:

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl" href="/First.xsl"?>
<lieferungen xmlns="urn:myspace:lieferungen"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:schemaLocation="urn:myspace:lieferungen ....">
  <artikel id="3526">
    <name>apfel</name>
    <preis stueckpreis="true">8.97</preis>
    <lieferant>Fa. Krause</lieferant>
  </artikel>
  <artikel id="7866">
    <name>Kirschen</name>
    <preis stueckpreis="false">10.45</preis>
    <lieferant>Fa. Helbig</lieferant>
  </artikel>
</lieferungen>

and here is my XSLT:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:template match="/">
    <html>
      <h1>The First XSLT in diesem Jahr</h1>
      <table>
        <tr>
          <td>Name</td>
          <td>Artikel</td>
          <td>Preis</td>
          <td>Liferant</td>
        </tr>
        <xsl:for-each select="artikel">
          <tr>
            <td>
              <xsl:value-of select="name"/>
            </td>
            <td>
              <xsl:value-of select="preis"/>
            </td>
            <td>
              <xsl:value-of select="lieferant"/>
            </td>
          </tr>
        </xsl:for-each>
      </table>
    </html>
  </xsl:template>
</xsl:stylesheet>

Federico Viotti · Accepted Answer · 2013-07-16 21:09:58Z

I offer another solution (also if I think that hr_117 offered a better one solution). Anyway I hope this may help you.

XML

<?xml version="1.0"?>
<lieferungen xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="urn:myspace:lieferungen ....">
   <artikel id="3526">
       <name>apfel</name>
       <preis stueckpreis="true">8.97</preis>
       <lieferant>Fa. Krause</lieferant>
   </artikel>
   <artikel id="7866">
        <name>Kirschen</name>
        <preis stueckpreis="false">10.45</preis>
        <lieferant>Fa. Helbig</lieferant>
   </artikel>
</lieferungen>

In the XML I removed the default namespace. And now the XSL:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"> 
<xsl:template match="/">
<html>
  <h1>The First XSLT in diesem Jahr</h1>
  <table border="1">
    <tr>
      <td>Name</td>
      <td>Artikel</td>
      <td>Preis</td>
      <td>Liferant</td>
    </tr>
    <xsl:for-each select="//lieferungen/artikel">
        <tr><xsl:apply-templates select="name"/>
            <td><xsl:value-of select="@id"/></td>
            <xsl:apply-templates select="preis|lieferant"/>
        </tr>
    </xsl:for-each>
  </table>
</html>
</xsl:template>

 <xsl:template match="name">
   <td><xsl:value-of select="node()"/></td>
 </xsl:template>

 <xsl:template match="preis">
    <td><xsl:value-of select="node()"/></td>
 </xsl:template>

 <xsl:template match="lieferant">
    <td><xsl:value-of select="node()"/></td>
 </xsl:template>

</xsl:stylesheet>

This generatre the following html:

<html>
    <h1>The First XSLT in diesem Jahr</h1>
    <table border="1">
       <tr>
           <td>Name</td>
           <td>Artikel</td>
           <td>Preis</td>
           <td>Liferant</td>
      </tr>
      <tr>
           <td>apfel</td>
           <td>3526</td>
           <td>8.97</td>
           <td>Fa. Krause</td>
      </tr>
      <tr>
           <td>Kirschen</td> 
           <td>7866</td>
           <td>10.45</td>
           <td>Fa. Helbig</td>
      </tr>
   </table>
</html>

hr_117 · Accepted Answer · 2013-07-16 16:23:55Z

There are only small problems in your xslt. The main one is, that your XML has an default namespace. Therefore you need to add this namespace with an prefix to your stylesheet. Something like: xmlns:my="urn:myspace:lieferungen"

Than you have to use the new prefix my for any access to an element form default namespace. E.g.:

<xsl:for-each select="my:artikel">

Second: Your for-each loop iterate over artikel therefor you need to be in liefrant element to make this work. Change your template to <xsl:template match="/*">

Therefor try this:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:my="urn:myspace:lieferungen" >
    <xsl:template match="/*">
        <html>
            <h1>The First XSLT in diesem Jahr</h1>
            <table>
                <tr>
                    <td>Name</td>
                    <td>Artikel</td>
                    <td>Preis</td>
                    <td>Liferant</td>
                </tr>
                <xsl:for-each select="my:artikel">
                    <tr>
                        <td>
                            <xsl:value-of select="my:name"/>
                        </td>
                        <td>
                            <xsl:value-of select="my:preis"/>
                        </td>
                        <td>
                            <xsl:value-of select="my:lieferant"/>
                        </td>
                    </tr>
                </xsl:for-each>
            </table>
        </html>
    </xsl:template>
</xsl:stylesheet>

Which will generate the following output:

<html xmlns:my="urn:myspace:lieferungen">
  <h1>The First XSLT in diesem Jahr</h1>
  <table>
    <tr>
      <td>Name</td>
      <td>Artikel</td>
      <td>Preis</td>
      <td>Liferant</td>
    </tr>
    <tr>
      <td>apfel</td>
      <td>8.97</td>
      <td>Fa. Krause</td>
    </tr>
    <tr>
      <td>Kirschen</td>
      <td>10.45</td>
      <td>Fa. Helbig</td>
    </tr>
  </table>
</html>

thnk you for your answer, I found somehow my problem, Th eproblem was the path of the Firs.xsl file in the xml file. If I put the absoulute path. It works, but now I have another problem. I can only show the HTML table and not the information in the xml file

Collectives™ on Stack Overflow

Showing xml elements in an HTML table using xslt

2 Answers 2

1 Comment

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related