cmake and libpthread

Question

I'm running RHEL 5.1 and use gcc.

How I tell cmake to add -pthread to compilation and linking?

Can you choose an answer for this?

Jared Burrows
– Jared Burrows

2015-05-09 23:46:22 +00:00
Commented May 9, 2015 at 23:46 — Jared Burrows
– Jared Burrows, Commented May 9, 2015 at 23:46
Dude, you gotta choose @Manuel's as the answer.

user4710450
– user4710450

2016-09-10 09:54:54 +00:00
Commented Sep 10, 2016 at 9:54 — user4710450
– user4710450, Commented Sep 10, 2016 at 9:54
@Ehsan thehouse's answer is way better! :-)

Ela782
– Ela782

2016-12-11 17:36:22 +00:00
Commented Dec 11, 2016 at 17:36 — Ela782
– Ela782, Commented Dec 11, 2016 at 17:36

Alex Reinking · Accepted Answer · 2020-06-19 00:05:33Z

310

@Manuel was part way there. You can add the compiler option as well, like this:

If you have CMake 3.1.0+, this becomes even easier:

set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)
target_link_libraries(my_app PRIVATE Threads::Threads)

If you are using CMake 2.8.12+, you can simplify this to:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  target_compile_options(my_app PUBLIC "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

Older CMake versions may require:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  set_property(TARGET my_app PROPERTY COMPILE_OPTIONS "-pthread")
  set_property(TARGET my_app PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

If you want to use one of the first two methods with CMake 3.1+, you will need set(THREADS_PREFER_PTHREAD_FLAG ON) there too.

edited Jun 19, 2020 at 0:05

Alex Reinking

20.7k8 gold badges68 silver badges110 bronze badges

answered Apr 25, 2015 at 23:29

thehouse

8,1377 gold badges35 silver badges33 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

mlt Over a year ago

It seems like e.g. CMake 3.0.2 won't set THREADS_HAVE_PTHREAD_ARG if pthread library was found (NOT CMAKE_HAVE_THREADS_LIBRARY), e.g. on Ubuntu 15.04 :(

j1elo Over a year ago

The version given for CMake 2.8.12+ won't work as intended, because of how the code works in /usr/share/cmake-2.8/Modules/FindThreads.cmake (eg. see here apt-browse.org/browse/ubuntu/trusty/main/all/cmake-data/…) Basically, THREADS_HAVE_PTHREAD_ARG is only set if the other variations of the flag weren't found (ie. -lpthread, -lpthread, or -lthread)

Chris Dodd Over a year ago

This gives the error "Cannot specify link libraries for target "my_app" which is not built by this project." -- how do you enable it universally without having to do it individually for each target?

Jay Over a year ago

Is the first still the easiest way in 2020/ cmake 3.17?

Jay Over a year ago

What happens if you don't set the THREADS_PREFER_PTHREAD_FLAG flag, just find and link?

|

Manuel · Accepted Answer · 2011-07-29 08:03:25Z

213

The following should be clean (using find_package) and work (the find module is called FindThreads):

cmake_minimum_required (VERSION 2.6) 
find_package (Threads)
add_executable (myapp main.cpp ...)
target_link_libraries (myapp ${CMAKE_THREAD_LIBS_INIT})

edited Jul 29, 2011 at 8:03

answered Jan 23, 2011 at 13:19

Manuel

6,4697 gold badges44 silver badges59 bronze badges

5 Comments

Simon Over a year ago

This doesn't work when using in a CXX only project. Does anyone know a nice workaround?

congusbongus Over a year ago

@Simon a bit late but please see this: stackoverflow.com/questions/15193785/…

bernardn Over a year ago

This solution works accros Mac OS X, Centos 6 and Solaris 10.

mlt Over a year ago

Note that this won't set -pthread compiler flag

Sandburg Over a year ago

is find_package also the approch on windows for .dll dependencies? Because usually, you have your lib dependencies in a thirdParty directory... but cmake looks in a IMPORTED_LOCATION path, isn't it?

iAdjunct · Accepted Answer · 2016-04-13 17:08:47Z

39

Here is the right anwser:

ADD_EXECUTABLE(your_executable ${source_files})

TARGET_LINK_LIBRARIES( your_executable
pthread
)

equivalent to

-lpthread

edited Apr 13, 2016 at 17:08

iAdjunct

3,1191 gold badge23 silver badges30 bronze badges

answered Oct 31, 2009 at 20:09

Nadir SOUALEM

3,5372 gold badges27 silver badges32 bronze badges

6 Comments

dimba Over a year ago

This is equivalent. "-pthread" donates much more - at compilation it's -D_REENTRANT, at link time -lpthread. On some system at even can be more than this.

Nadir SOUALEM Over a year ago

SET(CMAKE_CXX_FLAGS_DEBUG "... -lpthread") SET(CMAKE_CXX_FLAGS_RELEASE "... -lpthread")

Alexander Oh Over a year ago

this solution bricks as soon as you change from linux to freebsd or windows.

Overv Over a year ago

Doesn't work, "target_link_libraries(your_executable pthread)" is how it should be written.

Ela782 Over a year ago

This is not the right answer by any means. Even if you don't like thehouse's answer, and considering this was written in 2009, it's completely non-cross platform. Use thehouse's answer - and if you don't like it then go for something like target_link_libraries(target "$<$<CXX_COMPILER_ID:GNU>:-pthread>$<$<CXX_COMPILER_ID:Clang>:-pthreads>") which is at least target-based and doesn't fail on Windows and other platforms.

|

ChristianYami · Accepted Answer · 2021-01-14 01:17:07Z

7

target_compile_options solution above is wrong, it won't link the library.

Use:

SET(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -pthread")

OR

target_link_libraries(XXX PUBLIC pthread)

OR

set_target_properties(XXX PROPERTIES LINK_LIBRARIES -pthread)

edited Jan 14, 2021 at 1:17

ChristianYami

5781 gold badge9 silver badges17 bronze badges

answered Jan 12, 2021 at 8:41

WRFan

1751 silver badge3 bronze badges

1 Comment

alexchandel Over a year ago

This is brittle/outdated. Use find_package(Threads) and target_link_libraries(my_app PRIVATE Threads::Threads) instead.

Collectives™ on Stack Overflow

cmake and libpthread

4 Answers 4

6 Comments

5 Comments

6 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

6 Comments

5 Comments

6 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related