Using JSON Data with Coldfusion

Question

I've worked with JSON data in the past - mainly 'fudging' my way to a solution, and not really understanding why or how things work. I've come across an issue where the data being returned looks somewhat different to what I've seen before, and I can't find any examples that match it.

Here's an example of the data returned (via an API);

{"domain.co.uk":{"status":"available","classkey":"thirdleveldotuk"},"domain.net":{"status":"available","classkey":"dotnet"},"domain.com":{"status":"available","classkey":"domcno"}}

On my front-end, I need to return something like this -

domain.co.uk - available
domain.net - available
domain.com - available

Because the 'domain.com' etc value will always change, I can't map the names as I usually would (although it will always be 3 'rows' returned)

I've checked every CF Book I own, and read the online CF Docs, but I'm totally at a loss as to where to even start with this one!

Pointers much appreciated!

J.T. · Accepted Answer · 2013-04-05 17:50:46Z

10

If you run this with deserializeJSON(data), you'll see that you just end up with structures with nested structures. So, you can loop through your struct, grab the keys and then grab that key's status. In JSON terms, your JSON object has nested objects.

<cfset data = deserializeJSON(apiData) />
<cfset formattedData = [] />
<cfset tmp = {} />

<cfloop collection=#data# item="domain">
    <cfset tmp.domain = domain />
    <cfset tmp.status = data[domain]["status"] />
    <cfset arrayAppend(formattedData,duplicate(tmp)) />
</cfloop>

<cfdump var=#formattedData# />

answered Apr 5, 2013 at 17:50

J.T.

2,62618 silver badges32 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Lee Over a year ago

wow! Thanks @J.T. - that has worked a treat, and helped me with something else altogether!

Leigh · Accepted Answer · 2013-04-05 18:53:40Z

8

(This is really more of a comment, but is a bit too long ... )

I've worked with JSON data in the past - mainly 'fudging' my way to a solution, and not really understanding why or how things work

JSON strings are essentially just a representations of two objects:

arrays which are denoted by [] and
structures (or objects) which are denoted by {}

Looking at the API string, the braces {} indicate you are dealing with a structure:

     { "theKey": "theValue" }

In your case, the domain name is the structure key:

    { "domain.co.uk": "theValue" }

.. and the value is a nested structure containing two static keys: "status" and "classkey"

    { "theKey":  {"status":"available","classkey":"thirdleveldotuk"}  }

As with any structure, you can iterate through the keys dynamically using a for .. in loop, a collection loop if you prefer cfml.

     for (theKey in theStruct) {
         WriteDump( theKey ); // ie "domain.co.uk"
     }

Then inside the loop use associative array notation to grab the value, ie:

     theStatus = theStruct[ theKey ]["status"]; // "available"

     // ... OR
     theValue  = theStruct[ theKey ]; 
     theStatus = theValue.status;

That is all there is to it. You can use similar logic to access any type of nested structures.

edited Apr 5, 2013 at 18:53

answered Apr 5, 2013 at 18:31

Leigh

28.9k10 gold badges58 silver badges109 bronze badges

1 Comment

Lee Over a year ago

thanks for the detailed explanation, that's incredibly helpful! I really struggled to find a decent walkthrough of that anywhere else, so I'll most certainly be referring back to this in the future.

Collectives™ on Stack Overflow

Using JSON Data with Coldfusion

2 Answers 2

1 Comment

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related