Remove XML namespace declaration from XSLT output root?

Question

Having the following input XML:

<?xml version="1.0" encoding="utf-8" ?>
<customSettings xmlns:env="urn:schemas-test-env">
    <connectionStrings>
        <add name="Name" connectionString="None" providerName="" />
        <add name="Name" connectionString="Local"  providerName="" env:name="Local" />
        <add name="Name" connectionString="Dev"  providerName="" env:name="Dev"  />
    </connectionStrings>
    <appSettings>
        <add key="Name" value="Value" />
        <add key="Name" value="Local" env:name="Local" />
        <add key="Name" value="Dev" env:name="Dev" />
    </appSettings>
</customSettings>

and XSLT:

<?xml version="1.0" encoding="utf-8" ?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"

                xmlns:code="urn:schemas-test-code"
                xmlns:env="urn:schemas-test-env"
>
    <xsl:output version="1.0" encoding="utf-8" omit-xml-declaration="yes" indent="yes" />
    <xsl:strip-space elements="*" />

    <!-- Populate param value -->
    <xsl:param name="env" select="code:GetEnvironment()" />

    <!-- Copy content as is -->
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
    </xsl:template>

    <!-- Remove all add nodes with env:name not matching param -->
    <xsl:template match="add">
        <xsl:if test="not(@env:name != $env)">
            <xsl:call-template name="identity" />
        </xsl:if>
    </xsl:template>

    <!-- Remove all env:name attributes -->
    <xsl:template match="@env:name" />
</xsl:stylesheet>

I'm getting the following output XML:

<customSettings xmlns:env="urn:schemas-test-env">
  <connectionStrings>
    <add name="Name" connectionString="None" providerName="" />
    <add name="Name" connectionString="Local" providerName="" />
  </connectionStrings>
  <appSettings>
    <add key="Name" value="Value" />
    <add key="Name" value="Local" />
  </appSettings>
</customSettings>

How to remove namespace declaration from the root element?

Michael Kay · Accepted Answer · 2013-03-10 10:34:44Z

5

In XSLT 2.0 you can use

<xsl:copy copy-namespaces="no">

answered Mar 10, 2013 at 10:34

Michael Kay

165k11 gold badges97 silver badges173 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

abatishchev Over a year ago

I use .NET so unfortunately limited with 1.0.

Michael Kay Over a year ago

Not so, .NET is well served with XSLT 2.0 processors - there are two excellent ones, Saxon and XmlPrime.

abatishchev Over a year ago

Yes, sure, there are a lot but not out of the box. That's what I mean

JLRishe · Accepted Answer · 2013-03-10 04:59:44Z

4

If you replace this template:

<!-- Copy content as is -->
<xsl:template match="node()|@*" name="identity">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*" />
    </xsl:copy>
</xsl:template>

With these two templates:

<!-- Copy elements without copying their namespace declarations -->
<xsl:template match="*" name="identity">
  <xsl:element name="{name()}">
    <xsl:apply-templates select="node()|@*" />
  </xsl:element>
</xsl:template>

<!-- Copy content as is -->
<xsl:template match="node()|@*" priority="-2">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*" />
  </xsl:copy>
</xsl:template>

Then that should do it.

edited Mar 10, 2013 at 4:59

answered Mar 10, 2013 at 4:54

JLRishe

102k19 gold badges138 silver badges171 bronze badges

6 Comments

abatishchev Over a year ago

Is it possible do not use priority?

Ian Roberts Over a year ago

@abatischev no, because match="*" and match="node()" are the same priority by default.

nwellnhof Over a year ago

@abatishchev I think you don't need the priority attribute if you simply use <xsl:template match="text()|@*"><xsl:copy/></xsl:template> instead of the second template.

Ian Roberts Over a year ago

@nwellnhof it would have to be match="text()|comment()|processing-instruction()|@*"

JLRishe Over a year ago

@abatishchev Is there a reason you want to avoid using priority? An identity template should typically have lower priority than anything else in the XSLT, so making its priority extra low should probably not cause any issues.

|

Tormod Hystad · Accepted Answer · 2014-01-21 12:51:25Z

3

Have you tried adding exclude-result-prefixes="env" to your stylesheet declaration? Should work, like this:

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"

                xmlns:code="urn:schemas-test-code"
                xmlns:env="urn:schemas-test-env"
                exclude-result-prefixes="env"
>

answered Jan 21, 2014 at 12:51

Tormod Hystad

2,4251 gold badge21 silver badges15 bronze badges

Collectives™ on Stack Overflow

Remove XML namespace declaration from XSLT output root?

3 Answers 3

3 Comments

6 Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

6 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related