how to set http timeout using asp?

Question

This is my asp code

<%
http = server.createobject("microsoft.xmlhttp")
http.open "post", servleturl, false
http.setrequestheader "content-type", "application/x-www-form-urlencoded"
http.setrequestheader "accept-encoding", "gzip, deflate"
http.send  "request=" & sxml
http_response = http.responsetext
%>

i need to make TimeOut when the response not come in 15 seconds how?

gpinkas · Accepted Answer · 2015-07-02 16:18:03Z

18

You can also keep using the synchronous request by calling "SetTimeouts" like this:

<%
Dim http

Set http = Server.CreateObject("MSXML2.ServerXMLHTTP")
http.SetTimeouts 600000, 600000, 15000, 15000
http.Open "post", servleturl, false
http.SetRequestHeader "content-type", "application/x-www-form-urlencoded"
http.SetRequestHeader "accept-encoding", "gzip, deflate"
http.Send  "request=" & sxml

http_response = http.responsetext
%>

See here for docs.

The parameters are:

setTimeouts (long resolveTimeout, long connectTimeout, long sendTimeout, long receiveTimeout)

The setTimeouts method should be called before the open method. None of the parameters is optional.

edited Jul 2, 2015 at 16:18

answered Dec 27, 2012 at 14:36

gpinkas

2,5713 gold badges37 silver badges51 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Kul-Tigin Over a year ago

microsoft.xmlhttp is a version independent ProgID that corresponds to XMLHTTP which has not Timeouts method. Instead, use a ServerXMLHTTP instance. See here support.microsoft.com/kb/290761/en-us to get what's the difference between ServerXMLHTTP and XMLHTTP, especially in ASP applications. And the point is that OP wants a 15-seconds timeout. Due to your code, operation may exceed 15 seconds. This is not an asynchronous request btw.

gpinkas Over a year ago

@Kul-Tigin, you are right. I changed to SYNCHRONOUS, which is what the OP wants and changed the send/receive timeouts to 15 secs.

Kul-Tigin · Accepted Answer · 2012-12-27 14:00:27Z

Using waitForResponse method of ServerXMLHTTP instance after the .Send call is a proper way, I'd recommend.
Also to use .WaitForResponse, need to make an asynchronous call by setting True the third parameter of .Open method.

Const WAIT_TIMEOUT = 15
Dim http
Set http = Server.CreateObject("MSXML2.ServerXMLHTTP")
    http.open "POST", servleturl, True 'async request
    http.setrequestheader "content-type", "application/x-www-form-urlencoded"
    http.setrequestheader "accept-encoding", "gzip, deflate"
    http.send  "request=" & sxml
    If http.waitForResponse(WAIT_TIMEOUT) Then 'response ready
        http_response = http.responseText
    Else 'wait timeout exceeded
        'Handling timeout etc
        'http_response = "TIMEOUT" 
    End If
Set http = Nothing

Collectives™ on Stack Overflow

how to set http timeout using asp?

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related