5

I am programmatically creating a database connection object inside a simple procedure (not a method in a class). 

mydb:= TUniConnection.Create(nil);
mydb.Database:= knowledge_db_name;
mydb.LoginPrompt:= False;
mydb.Username:= aaa;
mydb.Password:= bbb;

now I need to handle errors and disconnections with other procedures. When I try to do:

mydb.OnError:= OnConnectionError;
mydb.OnConnectionLost:= OnConnectionLost;

The compiler tells me

[DCC Error] test.pas(373): E2009 Incompatible types: 'method pointer and regular procedure'

How can I work around this? Here are the definitions of the event procedures:

procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
Improve this question

4 Answers 4

Reset to default
20

If you don't have a suitable class to put the event handlers in you can define a dummy class and make the event handlers class procedures. Then you don't have to create an instance of the class but can assign mydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError;.

Here is an example - I use different events because I don't have TUniConnection but want to be sure everything compiles. :-)

type
  // Dummy class to hold event handlers:
  TXMLEventHandlers = class
    // Event handlers:
    class procedure OnBeforeOpen(Sender: TObject);
    class procedure OnAfterOpen(Sender: TObject);
  end;

class procedure TXMLEventHandlers.OnBeforeOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnBeforeOpen'), nil, 0)
end;

class procedure TXMLEventHandlers.OnAfterOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnAfterOpen'), nil, 0)
end;

procedure Test;
var
  xml: TXMLDocument;
begin
  xml := TXMLDocument.Create(nil);
  try
    // Note: No instance of `TXMLEventHandlers` must be created:
    xml.AfterOpen := TXMLEventHandlers.OnAfterOpen;
    xml.BeforeOpen := TXMLEventHandlers.OnBeforeOpen;

    xml.Active := True; // Calls the two event handlers
  finally
    xml.Free;
  end;
end;
Improve this answer
Sign up to request clarification or add additional context in comments.

6 Comments

Hmmm... this does mean that the "Self" passed to the class procedures is not a class type, it is an instance of a class. I am a little flabbergasted that this assigns without any error.
@Rudy, AFAIU an event variable is more or less a TMethod. Data is any pointer and Code points to a routine which takes something pointer-like (e.g. a class instance or "meta" variable) as its first argument. From an assembler point of view its all the same.
The event handler syntax is just syntactic sugar + some type checking added to the concept.
Yes, but exactly the "syntactic" part and the "type checking" make me wonder why it compiles.
From an assembler point of view it is all the same. But in Delphi, you can't assign a wrong type event handler to an event, so how come you can assign a class method to it?
|
4

If you don't want to instantiate an instance of a class on the heap, you could use record methods. I sometimes do that to avoid using the heap, but that approach could be convenient for your needs.

type
  TMyEventHandler = record
    procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
    procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
  end;

procedure TMyEventHandler.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ....
end;

procedure TMyEventHandler.OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ....
end;

var
  EventHandler: TEventHandler;//global variable

......

mydb.OnError := EventHandler.OnConnectionError;
mydb.OnConnectionLost := EventHandler.OnConnectionLost;
Improve this answer

1 Comment

I think Uli's answer is better than this. If I were you I would accept Uli's answer.
0

Your two event procedures need to be methods of a class, instead of local/global procedures. For example: 

procedure TForm1.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
Improve this answer

10 Comments

I know that, but the question is if I can do it without using a class (some kind of a cast maybe...).
If you don't have a class "ready" to put the event handlers in you can define a dummy class and make the event handlers class procedures. Then you don't have to create an instance of the class but can assign mydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError; .
@DavidHeffernan Can you provide an example of the global instance of the record?
@DavidHeffernan You have to try really hard to get the code wrong with a class procedure. The Self parameter for a class procedure is a class reference, not an instance, so you don't even get to accidentally access any class members you may have mistakenly added. A nil Self is much easier to accidentally get wrong.
@DavidHeffernan You indeed wouldn't have an instance, but the compiler wouldn't think you have an instance either (unlike with a nil cast). Try to access an instance member and get a compiler error.
|
0

While using a class method is a clean solution, it is possible to use a regular non-class procedure as an event handler, you just can't assign it directly, but you can assign it indirectly using the TMethod record. You will just have to add an explicit Self parameter to the procedure.

For example:

procedure OnConnectionError(Self: Pointer; Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ...
end;

procedure OnConnectionLost(Self: Pointer; Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ...
end;

var
  M: TMethod;
begin
  M.Data := ... whatever you want ...;
  M.Code := @OnConnectionError;
  mydb.OnError := TDAConnectionErrorEvent(M);

  M.Data := ... whatever you want ...;
  M.Code := @OnConnectionLost;
  mydb.OnConnectionLost := TConnectionLostEvent(M);
end;

Alternatively:

procedure OnConnectionError(Self: Pointer; Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ...
end;

procedure OnConnectionLost(Self: Pointer; Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ...
end;

var
  ErrorHandler: TDAConnectionErrorEvent;
  LostHandler: TConnectionLostEvent;
begin
  TMethod(ErrorHandler).Data := ... whatever you want ...;
  TMethod(ErrorHandler).Code := @OnConnectionError;
  mydb.OnError := ErrorHandler;

  TMethod(LostHandler).Data := ... whatever you want ...;
  TMethod(LostHandler).Code := @OnConnectionLost;
  mydb.OnConnectionLost := LostHandler;
end;

The benefit of this approach is that you can set the Self parameter to whatever value you want, which is useful for passing user-defined data into an event handler.

Improve this answer

Comments

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.