Deserialize JSON with multiple variable names to VB.NET object

A few points:

1. When you have a JSON object with arbitrary property names that are known only at runtime but that have some fixed schema for their value, use a Dictionary(Of String, Of TValue). In this case the schema for the value corresponds to a list of WorkDay objects, so use Dictionary(Of String, List(Of WorkDay)) for your root object type and eliminate the COLLECTION type entirely.

   You don't say what JSON serializer you are using, but dictionaries will work with both System.Text.Json and Newtonsoft.Json:

   Imports System.Text.Json
   
   JsonSerializer.Deserialize(Of Dictionary(Of String, List(Of WorkDay)))(json)
   

   or

   Imports Newtonsoft.Json
   
   Dim dict = JsonConvert.DeserializeObject(Of Dictionary(Of String, List(Of WorkDay)))(json)
   

   If using DataContractJsonSerializer you must first set DataContractJsonSerializerSettings.UseSimpleDictionaryFormat = true.

2. I recommend using properties instead of fields for all of your public class members, as System.Text.Json only serializes properties by default.

3. Several of your Minutes properties are numeric rather than textual:

     "targetWorkingTimeMinutes": 0,
     "breakDurationMinutes": 0,
     "workingTimeMinutes": 20,
   

   With some serializers (e.g. System.Text.Json) by default you need to use a numeric type such as Decimal or Integer to bind to numeric values, e.g.:

   Public Property targetWorkingTimeMinutes As Decimal
   Public Property breakDurationMinutes As Decimal
   Public Property workingTimeMinutes As Decimal
   

4. I recommend using the naming conventions from MSFT's Visual Basic Naming Conventions for your type names. Thus I changed WORKDAY to WorkDay.

5. Tools for generating .NET types from JSON generally will not automatically recognize when to use a Dictionary(Of String, of TValue) for a JSON object -- probably because there is no way to communicate to them that an object has variable names. (In fact many will generate duplicated types, one duplicate for each value.) Of the online tools mentioned in How to auto-generate a C# class file from a JSON string, only one, https://app.quicktype.io/#l=cs, will sometimes recognize dictionaries -- and when I tested it with your JSON with four root properties, it did not do so.

Putting it all together, your types should look like:

Public Class WorkDay
    Public Property workingTimes As New List(Of WorkTime)
    Public Property beginDate As String
    Public Property targetWorkingTimeMinutes As Decimal
    Public Property breakDurationMinutes As Decimal
    Public Property workingTimeMinutes As Decimal
    Public Property endDate As String
End Class

Public Class WorkTime
    Public Property endDateAndTime As String
    Public Property beginDateAndTime As String
    Public Property workingTimeType As WorkTimeType
    Public Property name As String
    Public Property type As String
    Public Property id As String
End Class

Public Class WorkTimeType
    Public Property type As String
    Public Property name As String
End Class

And sample code that deserializes your JSON could look like:

Dim dict = JsonSerializer.Deserialize(Of Dictionary(Of String, List(Of WorkDay)))(json)
    
For Each pair In dict
    Dim name = pair.Key
    Dim workDays = pair.Value
    
    Console.WriteLine($"Worker name {name}:")
    For Each workTime in workDays
        Console.WriteLine($"   Begin date: {workTime.beginDate}, Working Time Minutes: {workTime.workingTimeMinutes}, End Date: {workTime.endDate}")
    Next
Next

Sample System.Text.Json fiddle here and Json.NET fiddle here.