Salesforce batch class is not updating right

Question

I have a batch class that should update the Contact phone number with Related Account Phone number.

But it is not working as it wont update the records. Please find my code below.

However there is no error with the code:

global class CustomBatch implements Database.Batchable<Sobject> {

    global Database.QueryLocator start(Database.BatchableContext bc)
    {
        String query = 'select id,phone,Account.phone from Contact';
        system.debug('query');
        return Database.getQueryLocator(query);

    }
    global void execute(Database.BatchableContext bc,List<Contact> Scope){

        List<Contact> con = new List<Contact>();
        for(Contact c:con)
        {
            c.Phone = c.Account.Phone;
            con.add(c);
            system.debug('c');
        }
        update con;
    }

    global void finish(Database.BatchableContext bc){

        Messaging.SingleEmailMessage myemail = new Messaging.SingleEmailMessage();
        String[] toadd = new String[]{'[email protected]'};
           myemail.setToAddresses(toadd);
        myemail.setSubject('BatchCompleted');
        myemail.setPlainTextBody('Batch process has been completed successfully');
        Messaging.sendEmail(new Messaging.Email[]{myemail});
    }

}

Pasan Eeriyagama · Accepted Answer · 2018-03-01 00:02:39Z

2

Loop should be on List Scope, not List con in execute(). I would like to suggest below or similar execute() method instead.

void execute(Database.BatchableContext bc,List<Contact> Scope){

List<Contact> con = new List<Contact>();
for(Contact c:scope)
{
        c.Phone = c.Account.Phone;
        con.add(c);
        system.debug('c');
}
    update con;
}

edited Mar 1, 2018 at 0:02

answered Feb 28, 2018 at 10:39

Pasan Eeriyagama

2,58910 gold badges40 silver badges86 bronze badges

#2 wasn't an issue; just changing the for loop to "scope" from "con" would have fixed the issue.

sfdcfox
– sfdcfox

2018-02-28 15:54:54 +00:00
Commented Feb 28, 2018 at 15:54
Oh my bad, Yeah. Thanks @sfdcfox , updated answer accordingly.

Pasan Eeriyagama
– Pasan Eeriyagama

2018-03-01 00:04:12 +00:00
Commented Mar 1, 2018 at 0:04
The extra list con is unnecessary; you can update the scope directly

cropredy
– cropredy

2018-03-01 06:06:20 +00:00
Commented Mar 1, 2018 at 6:06

Add a comment |

sfdcfox · Accepted Answer · 2018-02-28 15:57:00Z

You simply needed to loop over the correct variable. The second list was not necessary, either:

global void execute(Database.BatchableContext bc,List<Contact> Scope){
    for(Contact c: scope)
    {
        c.Phone = c.Account.Phone;
    }
    update scope;
}

Don't make extra work for yourself when you don't need to. You rarely ever need a second "update list" when you already have a list to start with.

I'm really not sure who that person is that keeps posting examples of copying to a new list, but it's rarely ever necessary, and just produces inefficient code.

Stack Exchange Network

Salesforce batch class is not updating right

2 Answers 2

You must log in to answer this question.

Hot Network Questions