Can't retrieve IoT data with Arduino Ethernet shield

Question

I have an IFM AL1332 IO-Link master. https://media.ifm.com/CIP/mediadelivery/asset/3fe3e997b504a143aa0a54f558f218fd/80284134_EN.pdf?contentdisposition=inline

I can get data out of it via an ethernet connection to my computer and a browser. It looks like the following.

The "value" describes the status of port 1.

I want to do the same thing with an Arduino. I'm using an Arduino Mega and an Ethernet shield 2. Modified the web client code to the following.

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
byte mac[] = { 0xA8, 0x61, 0x0A, 0xAF, 0x15, 0x1C };

// if you don't want to use DNS (and reduce your sketch size)
// use the numeric IP instead of the name for the server:
IPAddress server(172, 16, 0, 110);  // numeric IP 

// Set the static IP address 
IPAddress ip(172, 16, 0, 101);

// Initialize the Ethernet client library
// with the IP address and port of the server
// that you want to connect to (port 80 is default for HTTP):
EthernetClient client;

// Variables to measure the speed
unsigned long beginMicros, endMicros;
unsigned long byteCount = 0;
bool printWebData = true;  // set to false for better speed measurement

void setup() {
  // You can use Ethernet.init(pin) to configure the CS pin
  //Ethernet.init(10);  // Most Arduino shields
  //Ethernet.init(5);   // MKR ETH Shield
  //Ethernet.init(0);   // Teensy 2.0
  //Ethernet.init(20);  // Teensy++ 2.0
  //Ethernet.init(15);  // ESP8266 with Adafruit FeatherWing Ethernet
  //Ethernet.init(33);  // ESP32 with Adafruit FeatherWing Ethernet

  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ;  // wait for serial port to connect. Needed for native USB port only
  }

  // start the Ethernet connection:
  Serial.println("Initialize Ethernet:");

  Ethernet.begin(mac, ip);

  // give the Ethernet shield a second to initialize:
  delay(1000);
  Serial.print("connecting to ");
  Serial.print(server);
  Serial.println("...");

  // if you get a connection, report back via serial:
  if (client.connect(server, 80)) {
    Serial.print("connected to ");
    Serial.println(client.remoteIP());
    // Make a HTTP request:
    client.println("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1");
    client.println();
  } else {
    // if you didn't get a connection to the server:
    Serial.println("connection failed");
  }
  beginMicros = micros();
}

void loop() {
  // if there are incoming bytes available
  // from the server, read them and print them:
  int len = client.available();
  if (len > 0) {
    byte buffer[80];
    if (len > 80) len = 80;
    client.read(buffer, len);
    if (printWebData) {
      Serial.write(buffer, len);  // show in the serial monitor (slows some boards)
    }
    byteCount = byteCount + len;
  } 

  // if the server's disconnected, stop the client:
  if (!client.connected()) {
    endMicros = micros();
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
    Serial.print("Received ");
    Serial.print(byteCount);
    Serial.print(" bytes in ");
    float seconds = (float)(endMicros - beginMicros) / 1000000.0;
    Serial.print(seconds, 4);
    float rate = (float)byteCount / seconds / 1000.0;
    Serial.print(", rate = ");
    Serial.print(rate);
    Serial.print(" kbytes/second");
    Serial.println();

    // do nothing forevermore:
    while (true) {
      delay(1);
    }
  }
}

Wehn I try it on the arduino I get the following.

Initialize Ethernet:

connecting to 172.16.0.110...

connected to 172.16.0.110

disconnecting.

Received 0 bytes in 32.1074, rate = 0.00 kbytes/second

No data arrives. As far as I can tell I'm sending the correct GET request. I inspected the elements of the pictured webpage.

What am I missing?

send the Host header and finish the request with an empty line (as the WebClient example does) — Juraj
– Juraj ♦, Commented Aug 23, 2024 at 14:46
@Juraj it is nearly at the end of void setup(). client.println("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1"); client.println(); — vini_i
– vini_i, Commented Aug 23, 2024 at 16:15

vini_i · Accepted Answer · 2024-08-23 17:55:49Z

0

client.println("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1");

The HTTP request was malformed. It was missing \r\n\r\n.

client.println("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1\r\n\r\n");

This is the statement that returned data from the server.

answered Aug 23, 2024 at 17:55

vini_i

1571 silver badge6 bronze badges

how many new lines do you need? println adds one, then you have two with \r\n\r\n and then you have one more client.println(). that is two empty lines more than HTTP requires.

Juraj
– Juraj ♦

2024-08-23 18:40:17 +00:00
Commented Aug 23, 2024 at 18:40
@Juraj That is what worked. I tried adding a single \r\n but that didn't do it. Adding two did the job. Can't tell you why

vini_i
– vini_i

2024-08-23 19:52:18 +00:00
Commented Aug 23, 2024 at 19:52
1

@Juraj After a bunch more digging and testing. It looks like the IFM device is extremely timing sensitive. Even a println() is not fast enough. The entire header information needs to be sent in a single line. client.print("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1\r\nHost: 172.16.0.110\r\n\r\n");It will respond properly to this line.

vini_i
– vini_i

2024-08-29 15:34:10 +00:00
Commented Aug 29, 2024 at 15:34

Add a comment |

liaifat85 · Accepted Answer · 2024-09-16 13:23:04Z

Your Arduino requests may be missing some headers. You can try this instead:

#include <SPI.h>
#include <Ethernet.h>

// Ethernet setup
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress server(172, 16, 0, 110);  // Replace with your server IP
EthernetClient client;

void setup() {
  Serial.begin(9600);
  while (!Serial) {
    ;  // Wait for serial port to connect
  }

  // Start the Ethernet connection
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    for (;;);
  }

  // Allow the Ethernet shield to initialize:
  delay(1000);

  if (client.connect(server, 80)) {
    Serial.println("connected");

    // Send HTTP GET request with additional headers
    client.println("GET /iolinkmaster/port[1]/iolinkdevice/pdin/getdata HTTP/1.1");
    client.println("Host: 172.16.0.110");
    client.println("Accept: text/html,application/xhtml+xml,application/xml;q=0.9,image/webp,*/*;q=0.8");
    client.println("User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/127.0.0.0 Safari/537.36");
    client.println("Accept-Encoding: gzip, deflate");
    client.println("Accept-Language: en-US,en;q=0.9");
    client.println("Connection: keep-alive");
    client.println("Upgrade-Insecure-Requests: 1");
    client.println();

  } else {
    Serial.println("connection failed");
  }
}

void loop() {
  // Read response from server
  while (client.connected()) {
    if (client.available()) {
      char c = client.read();
      Serial.print(c);
    }
  }

  // Disconnect when done
  if (!client.connected()) {
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }
}

Stack Exchange Network

Can't retrieve IoT data with Arduino Ethernet shield

2 Answers 2

Your Answer

Hot Network Questions

Can't retrieve IoT data with Arduino Ethernet shield

2 Answers 2

Your Answer

Sign up or log in

Post as a guest

Related

Hot Network Questions