emacs lisp call function with prefix argument programmatically

Question

I want to call a function from some elisp code as if I had called it interactively with a prefix argument. Specifically, I want to call grep with a prefix.

The closest I've gotten to making it work is using execute-extended-command, but that still requires that I type in the command I want to call with a prefix...

;; calls command with a prefix, but I have to type the command to be called...
(global-set-key (kbd "C-c m g")
                (lambda () (interactive)
                  (execute-extended-command t)))

The documentation says that execute-extended-command uses command-execute to execute the command read from the minibuffer, but I haven't been able to make it work:

;; doesn't call with prefix...
(global-set-key (kbd "C-c m g")
                (lambda () (interactive)
                  (command-execute 'grep t [t] t)))

Is there any way to call a function with a prefix yet non-interactively?

cjm · Accepted Answer · 2011-05-27 18:43:54Z

81

If I'm understanding you right, you're trying to make a keybinding that will act like you typed C-u M-x grep <ENTER>. Try this:

(global-set-key (kbd "C-c m g")
                (lambda () (interactive)
                  (setq current-prefix-arg '(4)) ; C-u
                  (call-interactively 'grep)))

Although I would probably make a named function for this:

(defun grep-with-prefix-arg ()
  (interactive)
  (setq current-prefix-arg '(4)) ; C-u
  (call-interactively 'grep))

(global-set-key (kbd "C-c m g") 'grep-with-prefix-arg)

answered May 27, 2011 at 18:43

cjm

62.2k9 gold badges133 silver badges179 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Gilles 'SO- stop being evil' Over a year ago

It doesn't matter in this particular case, but in general, I'd use (let ((current-prefix-arg '(4))) (call-interactively 'grep)) so that the behavior of subsequent functions called in the commands is not affected.

eugene Over a year ago

@cjm why 4? C-u is 4?

yPhil · Accepted Answer · 2021-01-31 09:12:21Z

17

Or you could just use a keyboard macro

(global-set-key (kbd "s-l") (kbd "C-u C-SPC"))

In this example, the key combination "s-l" (s ("super") is the "windows logo" key on a PC keyboard) will go up the mark ring, just like you if typed "C-u C-SPC".

edited Jan 31, 2021 at 9:12

answered Jul 27, 2012 at 12:57

yPhil

8,4375 gold badges61 silver badges92 bronze badges

Collectives™ on Stack Overflow

emacs lisp call function with prefix argument programmatically

2 Answers 2

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related