Batch scripting not assigning variable as expected

Question

I'm working on a batch script which will assign a variable string and then trim it. I'm facing two issues:

The variables are not assigning properly. It is taking last value from from the variable file.
The variables are not assigning the first time I run the script. I need to run the script second time to see if the variables have been assigned. On third run, I can see the trim is working.

My script looks like this:

@echo off
for /f "tokens=*" %%a in ('findstr "W3SVCWINSRVRHOSTS" "C:\Data\SiebelAdmin\Commands\file.txt"') do (
for /f "tokens=2 delims==" %%b in ("%%a") do (
for %%c in (%%b) do (
echo in loop
set str=%%c
echo %%c
echo.%str%
set str=%str:~-6%
echo.%str%
)))

The output looks like this on third run:

> C:\Users\parthod\Desktop>b.bat
in loop
xsj-uvapoms72
7.2.27
7.2.27
in loop
xsj-uvapoms82
7.2.27
7.2.27
in loop
172.17.2.26
7.2.27
7.2.27
in loop
172.17.2.27
7.2.27
7.2.27

Community · Accepted Answer · 2017-05-23 10:32:38Z

3

You fell into the delayed expansion trap -- try this:

@echo off
setlocal EnableDelayedExpansion
for /f "tokens=*" %%a in ('findstr "W3SVCWINSRVRHOSTS" "C:\Data\SiebelAdmin\Commands\file.txt"') do (
for /f "tokens=2 delims==" %%b in ("%%a") do (
for %%c in (%%b) do (
echo in loop
set str=%%c
echo %%c
echo.!str!
set str=!str:~-6!
echo.!str!
)))
endlocal & set str=%str%

In between the setlocal/endlocal block, delayed variable expansion is active. To actually use this feature enclose the variables by !! rather than %%.
Since setlocal sets up a new namespace for variables, the compound endlocal & set statement is required to transfer the value of str beyond the block.

edited May 23, 2017 at 10:32

CommunityBot

11 silver badge

answered Jul 30, 2015 at 9:03

aschipfl

35.3k12 gold badges62 silver badges106 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

RaRdEvA Over a year ago

The key point is the "!" instead of "%"; I was struggling with this but your explanation sets it clear.

Collectives™ on Stack Overflow

Batch scripting not assigning variable as expected

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest